Rules for integrands involving exponentials of inverse hyperbolic tangents

1.  ∫u (e^(n ArcTanh[a x]))dx

1.  ∫(x^m) (e^(n ArcTanh[a x]))dx

1:  ∫(x^m)(e^(n ArcTanh[a x]))dx  when  ((n-1)/2)∈ℤ

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1+z))^((n+1)/2))/((((1-z))^((n-1)/2))(Sqrt[1-(z^2)])))

Rule: If ((n-1)/2)∈ℤ, then

∫(x^m)(e^(n ArcTanh[a x]))dx  ⟶  ∫(x^m)((((1+a x))^((n+1)/2))/((((1-a x))^((n-1)/2))(Sqrt[1-(a^2) (x^2)])))dx

Program code:

Int[E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  Int[((1+a*x)^((n+1)/2)/((1-a*x)^((n-1)/2)*Sqrt[1-a^2*x^2])),x] /;
FreeQ[a,x] && IntegerQ[(n-1)/2]

Int[x_^m_.*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  Int[x^m*((1+a*x)^((n+1)/2)/((1-a*x)^((n-1)/2)*Sqrt[1-a^2*x^2])),x] /;
FreeQ[{a,m},x] && IntegerQ[(n-1)/2]

2:  ∫(x^m) (e^(n ArcTanh[a x]))dx  when  ((n-1)/2)∉ℤ

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1+z))^(n/2))/(((1-z))^(n/2)))

Rule: If ((n-1)/2)∉ℤ, then

∫(x^m) (e^(n ArcTanh[a x]))dx  ⟶  ∫(x^m)((((1+a x))^(n/2))/(((1-a x))^(n/2)))dx

Program code:

Int[E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  Int[(1+a*x)^(n/2)/(1-a*x)^(n/2),x] /;
FreeQ[{a,n},x] && Not[IntegerQ[(n-1)/2]]

Int[x_^m_.*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  Int[x^m*(1+a*x)^(n/2)/(1-a*x)^(n/2),x] /;
FreeQ[{a,m,n},x] && Not[IntegerQ[(n-1)/2]]

2.  ∫u(((c+d x))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) (c^2)-(d^2)==0

1:  ∫(((e+f x))^m) (((c+d x))^p) (e^(n ArcTanh[a x]))dx  when  a c+d==0 ∧ ((n-1)/2)∈ℤ ∧ (p∈ℤ ∨ p-(n/2)==0 ∨ p-(n/2)-1==0)

Derivation: Algebraic simplification

Basis: If  a c+d==0 ∧ n∈ℤ, then (((c+d x))^n) (e^(n ArcTanh[a x]))==(c^n) (((1-(a^2) (x^2)))^(n/2))

Note: The condition p∈ℤ ∨ p-(n/2)==0 ∨ p-(n/2)-1==0 should be removed when the rules for integrands of the form (((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p) when c (d^2)-b d e+a (e^2)==0 are strengthened.

Rule: If  a c+d==0 ∧ ((n-1)/2)∈ℤ ∧ (p∈ℤ ∨ p-(n/2)==0 ∨ p-(n/2)-1==0), then

∫(((e+f x))^m) (((c+d x))^p) (e^(n ArcTanh[a x]))dx  ⟶  (c^n)∫(((e+f x))^m) (((c+d x))^(p-n)) (((1-(a^2) (x^2)))^(n/2))dx

Program code:

Int[(c_+d_.*x_)^p_.*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  c^n*Int[(c+d*x)^(p-n)*(1-a^2*x^2)^(n/2),x] /;
FreeQ[{a,c,d,p},x] && EqQ[a*c+d,0] && IntegerQ[(n-1)/2] && IntegerQ[2*p]

Int[(e_.+f_.*x_)^m_.*(c_+d_.*x_)^p_.*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  c^n*Int[(e+f*x)^m*(c+d*x)^(p-n)*(1-a^2*x^2)^(n/2),x] /;
FreeQ[{a,c,d,e,f,m,p},x] && EqQ[a*c+d,0] && IntegerQ[(n-1)/2] && (IntegerQ[p] || EqQ[p,n/2] || EqQ[p-n/2-1,0]) && IntegerQ[2*p]

2:  ∫u(((c+d x))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) (c^2)-(d^2)==0 ∧ (p∈ℤ ∨ c>0)

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1+z))^(n/2))/(((1-z))^(n/2)))

Note: Since (a^2) (c^2)-(d^2)==0, the factor (((1+((d x)/c)))^p) will combine with one of the factors (((1+a x))^(n/2)) or (((1-a x))^(-n/2)).

Rule: If  (a^2) (c^2)-(d^2)==0 ∧ (p∈ℤ ∨ c>0), then

∫u(((c+d x))^p) (e^(n ArcTanh[a x]))dx  ⟶  (c^p)∫u(((1+((d x)/c)))^p) ((((1+a x))^(n/2))/(((1-a x))^(n/2)))dx

Program code:

Int[u_.*(c_+d_.*x_)^p_.*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  c^p*Int[u*(1+d*x/c)^p*(1+a*x)^(n/2)/(1-a*x)^(n/2),x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[a^2*c^2-d^2,0] && (IntegerQ[p] || GtQ[c,0])

3:  ∫u(((c+d x))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) (c^2)-(d^2)==0 ∧ ¬(p∈ℤ ∨ c>0)

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1+z))^(n/2))/(((1-z))^(n/2)))

Note: Since (a^2) (c^2)-(d^2)==0, the factor (((c+d x))^p) will combine with one of the factors (((1+a x))^(n/2)) or (((1-a x))^(-n/2)) after piecewise constant extraction.

Rule: If  (a^2) (c^2)-(d^2)==0 ∧ ¬(p∈ℤ ∨ c>0), then

∫u(((c+d x))^p) (e^(n ArcTanh[a x]))dx  ⟶  ∫((u(((c+d x))^p)(((1+a x))^(n/2)))/(((1-a x))^(n/2)))dx

Program code:

Int[u_.*(c_+d_.*x_)^p_.*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  Int[u*(c+d*x)^p*(1+a*x)^(n/2)/(1-a*x)^(n/2),x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[a^2*c^2-d^2,0] && Not[IntegerQ[p] || GtQ[c,0]]

3.  ∫u(((c+(d/x)))^p) (e^(n ArcTanh[a x]))dx  when  (c^2)-(a^2)(d^2)==0

1:  ∫u(((c+(d/x)))^p) (e^(n ArcTanh[a x]))dx  when  (c^2)-(a^2)(d^2)==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  p∈ℤ, then (((c+(d/x)))^p)==((d^p)/(x^p))(((1+((c x)/d)))^p)

Rule: If  (c^2)-(a^2)(d^2)==0 ∧ p∈ℤ, then

∫u(((c+(d/x)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (d^p)∫(u/(x^p))(((1+((c x)/d)))^p) (e^(n ArcTanh[a x]))dx

Program code:

Int[u_.*(c_+d_./x_)^p_.*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  d^p*Int[u*(1+c*x/d)^p*E^(n*ArcTanh[a*x])/x^p,x] /;
FreeQ[{a,c,d,n},x] && EqQ[c^2-a^2*d^2,0] && IntegerQ[p]

2.  ∫u(((c+(d/x)))^p) (e^(n ArcTanh[a x]))dx  when  (c^2)-(a^2)(d^2)==0 ∧ p∉ℤ

1.  ∫u(((c+(d/x)))^p) (e^(n ArcTanh[a x]))dx  when  (c^2)-(a^2)(d^2)==0 ∧ p∉ℤ ∧ (n/2)∈ℤ

1:  ∫u(((c+(d/x)))^p) (e^(n ArcTanh[a x]))dx  when  (c^2)-(a^2)(d^2)==0 ∧ p∉ℤ ∧ (n/2)∈ℤ ∧ c>0

Derivation: Algebraic simplification

Basis: If  (n/2)∈ℤ, then (e^(n ArcTanh[z]))==((((1+z))^(n/2))/(((1-z))^(n/2)))==(((-1))^(n/2))((((1+(1/z)))^(n/2))/(((1-(1/z)))^(n/2)))

Note: Since (c^2)-(a^2)(d^2)==0, the factor (((1+((d )/(c x))))^p) will combine with the factor (((1+(1/(a x))))^(n/2)) or (((1-(1/(a x))))^(-n/2)).

Rule: If  (c^2)-(a^2)(d^2)==0 ∧ p∉ℤ ∧ (n/2)∈ℤ ∧ c>0, then

∫u(((c+(d/x)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (((-1))^(n/2))(c^p)∫u(((1+((d )/(c x))))^p) ((((1+(1/(a x))))^(n/2))/(((1-(1/(a x))))^(n/2)))dx

Program code:

Int[u_.*(c_+d_./x_)^p_*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  (-1)^(n/2)*c^p*Int[u*(1+d/(c*x))^p*(1+1/(a*x))^(n/2)/(1-1/(a*x))^(n/2),x] /;
FreeQ[{a,c,d,p},x] && EqQ[c^2-a^2*d^2,0] && Not[IntegerQ[p]] && IntegerQ[n/2] && GtQ[c,0]

2:  ∫u(((c+(d/x)))^p) (e^(n ArcTanh[a x]))dx  when  (c^2)-(a^2)(d^2)==0 ∧ p∉ℤ ∧ (n/2)∈ℤ ∧ c≯0

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1+z))^(n/2))/(((1-z))^(n/2)))

Rule: If  (c^2)-(a^2)(d^2)==0 ∧ p∉ℤ ∧ (n/2)∈ℤ ∧ c≯0, then

∫u(((c+(d/x)))^p) (e^(n ArcTanh[a x]))dx  ⟶  ∫u(((c+(d/x)))^p) ((((1+a x))^(n/2))/(((1-a x))^(n/2)))dx

Program code:

Int[u_.*(c_+d_./x_)^p_*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  Int[u*(c+d/x)^p*(1+a*x)^(n/2)/(1-a*x)^(n/2),x] /;
FreeQ[{a,c,d,p},x] && EqQ[c^2-a^2*d^2,0] && Not[IntegerQ[p]] && IntegerQ[n/2] && Not[GtQ[c,0]]

2:  ∫u(((c+(d/x)))^p) (e^(n ArcTanh[a x]))dx  when  (c^2)-(a^2)(d^2)==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)(((x^p)(((c+(d/x)))^p))/(((1+((c x)/d)))^p))==0

Rule: If  (c^2)-(a^2)(d^2)==0 ∧ p∉ℤ, then

∫u(((c+(d/x)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (((x^p)(((c+(d/x)))^p))/(((1+((c x)/d)))^p))∫(u/(x^p))(((1+((c x)/d)))^p) (e^(n ArcTanh[a x]))dx

Program code:

Int[u_.*(c_+d_./x_)^p_*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  x^p*(c+d/x)^p/(1+c*x/d)^p*Int[u*(1+c*x/d)^p*E^(n*ArcTanh[a*x])/x^p,x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[c^2-a^2*d^2,0] && Not[IntegerQ[p]]

4.  ∫u(((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0

1.  ∫(((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0

1.  ∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ p<-1 ∧ n∉ℤ

1:  ∫((e^(n ArcTanh[a x]))/(((c+d (x^2)))^(3/2)))dx  when  (a^2) c+d==0 ∧ n∉ℤ

Rule: If  (a^2) c+d==0 ∧ n∉ℤ, then

∫((e^(n ArcTanh[a x]))/(((c+d (x^2)))^(3/2)))dx  ⟶  (((n-a x)(e^(n ArcTanh[a x])))/(a c ((n^2)-1) (Sqrt[c+d (x^2)])))

Program code:

Int[E^(n_*ArcTanh[a_.*x_])/(c_+d_.*x_^2)^(3/2),x_Symbol] :=
  (n-a*x)*E^(n*ArcTanh[a*x])/(a*c*(n^2-1)*Sqrt[c+d*x^2]) /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[n]]

2:  ∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ p<-1 ∧ n∉ℤ ∧ (n^2)-4 (((p+1))^2)≠0

Derivation: ???

Rule: If  (a^2) c+d==0 ∧ p<-1 ∧ n∉ℤ ∧ (n^2)-4 (((p+1))^2)≠0, then

∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (((n+2 a (p+1) x) (((c+d (x^2)))^(p+1))(e^(n ArcTanh[a x])))/(a c ((n^2)-4 (((p+1))^2))))-((2 (p+1) (2 p+3))/(c((n^2)-4 (((p+1))^2))))∫(((c+d (x^2)))^(p+1))(e^(n ArcTanh[a x]))dx

Program code:

Int[(c_+d_.*x_^2)^p_*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  (n+2*a*(p+1)*x)*(c+d*x^2)^(p+1)*E^(n*ArcTanh[a*x])/(a*c*(n^2-4*(p+1)^2)) - 
  2*(p+1)*(2*p+3)/(c*(n^2-4*(p+1)^2))*Int[(c+d*x^2)^(p+1)*E^(n*ArcTanh[a*x]),x] /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && LtQ[p,-1] && Not[IntegerQ[n]] && NeQ[n^2-4*(p+1)^2,0] && IntegerQ[2*p]

2.  ∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ (p∈ℤ ∨ c>0)

1:  ∫((e^(n ArcTanh[a x]))/(c+d (x^2)))dx  when  (a^2) c+d==0 ∧ (n/2)∉ℤ

Rule: If  (a^2) c+d==0 ∧ (n/2)∉ℤ, then

∫((e^(n ArcTanh[a x]))/(c+d (x^2)))dx  ⟶  ((e^(n ArcTanh[a x]))/(a c n))

Program code:

Int[E^(n_.*ArcTanh[a_.*x_])/(c_+d_.*x_^2),x_Symbol] :=
  E^(n*ArcTanh[a*x])/(a*c*n) /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[n/2]]

2.  ∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ p∈ℤ ∧ ((n+1)/2)∈ℤ

1:  ∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ p∈ℤ ∧ ((n+1)/2)∈(SuperPlus[ℤ])

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1+z))^n)/(((1-(z^2)))^(n/2)))

Rule: If  (a^2) c+d==0 ∧ p∈ℤ ∧ ((n+1)/2)∈(SuperPlus[ℤ]), then

∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (c^p)∫(((1-(a^2)(x^2)))^p) ((((1+a x))^n)/(((1-(a^2)(x^2)))^(n/2)))dx  ⟶  (c^p)∫(((1-(a^2)(x^2)))^(p-(n/2)))(((1+a x))^n)dx

Program code:

Int[(c_+d_.*x_^2)^p_.*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  c^p*Int[(1-a^2*x^2)^(p-n/2)*(1+a*x)^n,x] /;
FreeQ[{a,c,d,p},x] && EqQ[a^2*c+d,0] && IntegerQ[p] && IGtQ[(n+1)/2,0] && Not[IntegerQ[p-n/2]]

2:  ∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ p∈ℤ ∧ ((n-1)/2)∈(SuperMinus[ℤ])

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1-(z^2)))^(n/2))/(((1-z))^n))

Rule: If  (a^2) c+d==0 ∧ p∈ℤ ∧ ((n-1)/2)∈(SuperMinus[ℤ]), then

∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (c^p)∫(((1-(a^2)(x^2)))^p) ((((1-(a^2)(x^2)))^(n/2))/(((1-a x))^n))dx  ⟶  (c^p)∫((((1-(a^2) (x^2)))^(p+(n/2)))/(((1-a x))^n))dx

Program code:

Int[(c_+d_.*x_^2)^p_.*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  c^p*Int[(1-a^2*x^2)^(p+n/2)/(1-a*x)^n,x] /;
FreeQ[{a,c,d,p},x] && EqQ[a^2*c+d,0] && IntegerQ[p] && ILtQ[(n-1)/2,0] && Not[IntegerQ[p-n/2]]

3:  ∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ (p∈ℤ ∨ c>0)

Derivation: Algebraic simplification

Basis: If  (a^2) c+d==0 ∧ (p∈ℤ ∨ c>0), then (((c+d (x^2)))^p)==(c^p) (((1-a x))^p) (((1+a x))^p)

Basis: (e^(n ArcTanh[z]))==((((1+z))^(n/2))/(((1-z))^(n/2)))

Rule: If  (a^2) c+d==0 ∧ (p∈ℤ ∨ c>0), then

∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (c^p)∫(((1-a x))^p)(((1+a x))^p)  ((((1+a x))^(n/2))/(((1-a x))^(n/2)))dx  ⟶  (c^p)∫(((1-a x))^(p-(n/2))) (((1+a x))^(p+(n/2)))dx

Program code:

Int[(c_+d_.*x_^2)^p_.*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  c^p*Int[(1-a*x)^(p-n/2)*(1+a*x)^(p+n/2),x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[a^2*c+d,0] && (IntegerQ[p] || GtQ[c,0])

3.  ∫(((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0)

1.  ∫(((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∈ℤ

1:  ∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∈(SuperPlus[ℤ])

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1+z))^n)/(((1-(z^2)))^(n/2)))

Basis: If  (a^2) c+d==0 ∧ (n/2)∈ℤ, then (((1-(a^2) (x^2)))^(-n/2))==(c^(n/2)) (((c+d (x^2)))^(-n/2))

Rule: If  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∈(SuperPlus[ℤ]), then

∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  ∫(((c+d (x^2)))^p) ((((1+a x))^n)/(((1-(a^2)(x^2)))^(n/2)))dx  ⟶  (c^(n/2))∫(((c+d (x^2)))^(p-(n/2)))(((1+a x))^n)dx

Program code:

Int[(c_+d_.*x_^2)^p_.*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  c^(n/2)*Int[(c+d*x^2)^(p-n/2)*(1+a*x)^n,x] /;
FreeQ[{a,c,d,p},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[p] || GtQ[c,0]] && IGtQ[n/2,0]

2:  ∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∈(SuperMinus[ℤ])

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1-(z^2)))^(n/2))/(((1-z))^n))

Basis: If  (a^2) c+d==0 ∧ (n/2)∈ℤ, then (((1-(a^2) (x^2)))^(n/2))==(1/(c^(n/2))) (((c+d (x^2)))^(n/2))

Rule: If  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∈(SuperMinus[ℤ]), then

∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  ∫(((c+d (x^2)))^p) ((((1-(a^2)(x^2)))^(n/2))/(((1-a x))^n))dx  ⟶  (1/(c^(n/2)))∫((((c+d (x^2)))^(p+(n/2)))/(((1-a x))^n))dx

Program code:

Int[(c_+d_.*x_^2)^p_.*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  1/c^(n/2)*Int[(c+d*x^2)^(p+n/2)/(1-a*x)^n,x] /;
FreeQ[{a,c,d,p},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[p] || GtQ[c,0]] && ILtQ[n/2,0]

2:  ∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (a^2) c+d==0, then (∂_x)((((c+d (x^2)))^p)/(((1-(a^2)(x^2)))^p))==0

Rule: If  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0), then

∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (((c^(IntPart[p])) (((c+d (x^2)))^(FracPart[p])))/(((1-(a^2)(x^2)))^(FracPart[p])))∫(((1-(a^2)(x^2)))^p) (e^(n ArcTanh[a x]))dx

Program code:

Int[(c_+d_.*x_^2)^p_*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  c^IntPart[p]*(c+d*x^2)^FracPart[p]/(1-a^2*x^2)^FracPart[p]*Int[(1-a^2*x^2)^p*E^(n*ArcTanh[a*x]),x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[p] || GtQ[c,0]]

2.  ∫(x^m)(((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0

1.  ∫x (((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ p<-1 ∧ n∉ℤ

1:  ∫((x (e^(n ArcTanh[a x])))/(((c+d (x^2)))^(3/2)))dx  when  (a^2) c+d==0 ∧ n∉ℤ

Rule: If  (a^2) c+d==0 ∧ n∉ℤ, then

∫((x (e^(n ArcTanh[a x])))/(((c+d (x^2)))^(3/2)))dx  ⟶  (((1-a n x) (e^(n ArcTanh[a x])))/(d ((n^2)-1) (Sqrt[c+d (x^2)])))

Program code:

Int[x_*E^(n_*ArcTanh[a_.*x_])/(c_+d_.*x_^2)^(3/2),x_Symbol] :=
  (1-a*n*x)*E^(n*ArcTanh[a*x])/(d*(n^2-1)*Sqrt[c+d*x^2]) /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[n]]

2:  ∫x (((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ p<-1 ∧ n∉ℤ

Derivation: Integration by parts

Basis: (∂_x)((((c+d (x^2)))^(p+1))/(2 d (p+1)))==x (((c+d (x^2)))^p)

Rule: If  (a^2) c+d==0 ∧ p<-1 ∧ n∉ℤ, then

∫x (((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  ⟶  (((((c+d (x^2)))^(p+1)) (e^(n ArcTanh[a x])))/(2 d (p+1)))-((a c n)/(2 d (p+1)))∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx

  ⟶  -(((2(p+1)+a n x)(((c+d (x^2)))^(p+1))(e^(n ArcTanh[a x])))/(d ((n^2)-4(((p+1))^2))))-((n(2p+3))/(a c ((n^2)-4(((p+1))^2))))∫(((c+d (x^2)))^(p+1)) (e^(n ArcTanh[a x]))dx

Program code:

Int[x_*(c_+d_.*x_^2)^p_*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  (c+d*x^2)^(p+1)*E^(n*ArcTanh[a*x])/(2*d*(p+1)) - a*c*n/(2*d*(p+1))*Int[(c+d*x^2)^p*E^(n*ArcTanh[a*x]),x] /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && LtQ[p,-1] && Not[IntegerQ[n]] && IntegerQ[2*p]

(* Int[x_*(c_+d_.*x_^2)^p_*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  -(2*(p+1)+a*n*x)*(c+d*x^2)^(p+1)*E^(n*ArcTanh[a*x])/(d*(n^2-4*(p+1)^2)) - 
  n*(2*p+3)/(a*c*(n^2-4*(p+1)^2))*Int[(c+d*x^2)^(p+1)*E^(n*ArcTanh[a*x]),x] /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && LeQ[p,-1] && NeQ[n^2-4*(p+1)^2,0] && Not[IntegerQ[n]] *)

2.  ∫(x^2) (((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ p<-1 ∧ n∉ℤ

1:  ∫(x^2) (((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ (n^2)+2(p+1)==0 ∧ n∉ℤ

Rule: If  (a^2) c+d==0 ∧ (n^2)+2(p+1)==0 ∧ n∉ℤ, then

∫(x^2) (((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (((1-a n x) (((c+d (x^2)))^(p+1)) (e^(n ArcTanh[a x])))/(a d n ((n^2)-1)))

Program code:

Int[x_^2*(c_+d_.*x_^2)^p_.*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  (1-a*n*x)*(c+d*x^2)^(p+1)*E^(n*ArcTanh[a*x])/(a*d*n*(n^2-1)) /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && EqQ[n^2+2*(p+1),0] && Not[IntegerQ[n]]

2:  ∫(x^2) (((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ p<-1 ∧ n∉ℤ ∧ (n^2)-4(((p+1))^2)≠0

Derivation: Algebraic expansion and ???

Basis: (x^2) (((c+d (x^2)))^p)==-((c (((c+d (x^2)))^p))/d)+((((c+d (x^2)))^(p+1))/d)

Rule: If  (a^2) c+d==0 ∧ p<-1 ∧ n∉ℤ ∧ (n^2)-4(((p+1))^2)≠0, then

∫(x^2) (((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  ⟶  -(c/d) ∫(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx+(1/d)∫(((c+d (x^2)))^(p+1)) (e^(n ArcTanh[a x]))dx

  ⟶  -(((n+2 (p+1) a x) (((c+d (x^2)))^(p+1))(e^(n ArcTanh[a x])))/(a d((n^2)-4 (((p+1))^2))))+(((n^2)+2(p+1))/(d((n^2)-4 (((p+1))^2))))∫(((c+d (x^2)))^(p+1)) (e^(n ArcTanh[a x]))dx

Program code:

Int[x_^2*(c_+d_.*x_^2)^p_*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  -(n+2*(p+1)*a*x)*(c+d*x^2)^(p+1)*E^(n*ArcTanh[a*x])/(a*d*(n^2-4*(p+1)^2)) + 
  (n^2+2*(p+1))/(d*(n^2-4*(p+1)^2))*Int[(c+d*x^2)^(p+1)*E^(n*ArcTanh[a*x]),x] /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && LtQ[p,-1] && Not[IntegerQ[n]] && NeQ[n^2-4*(p+1)^2,0] && IntegerQ[2*p]

3.  ∫(x^m) (((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ (p∈ℤ ∨ c>0)

1.  ∫(x^m) (((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ (p∈ℤ ∨ c>0) ∧ ((n+1)/2)∈ℤ

1:  ∫(x^m) (((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ (p∈ℤ ∨ c>0) ∧ ((n+1)/2)∈(SuperPlus[ℤ])

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1+z))^n)/(((1-(z^2)))^(n/2)))

Rule: If  (a^2) c+d==0 ∧ (p∈ℤ ∨ c>0) ∧ ((n+1)/2)∈(SuperPlus[ℤ]), then

∫(x^m) (((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (c^p)∫(x^m) (((1-(a^2)(x^2)))^p) ((((1+a x))^n)/(((1-(a^2)(x^2)))^(n/2)))dx  ⟶  (c^p)∫(x^m) (((1-(a^2)(x^2)))^(p-(n/2)))(((1+a x))^n)dx

Program code:

Int[x_^m_.*(c_+d_.*x_^2)^p_.*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  c^p*Int[x^m*(1-a^2*x^2)^(p-n/2)*(1+a*x)^n,x] /;
FreeQ[{a,c,d,m,p},x] && EqQ[a^2*c+d,0] && (IntegerQ[p] || GtQ[c,0]) && IGtQ[(n+1)/2,0] && Not[IntegerQ[p-n/2]]

2:  ∫(x^m) (((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ (p∈ℤ ∨ c>0) ∧ ((n-1)/2)∈(SuperMinus[ℤ])

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1-(z^2)))^(n/2))/(((1-z))^n))

Rule: If  (a^2) c+d==0 ∧ (p∈ℤ ∨ c>0) ∧ ((n-1)/2)∈(SuperMinus[ℤ]), then

∫(x^m) (((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (c^p)∫(x^m) (((1-(a^2)(x^2)))^p) ((((1-(a^2)(x^2)))^(n/2))/(((1-a x))^n))dx  ⟶  (c^p)∫(((x^m) (((1-(a^2) (x^2)))^(p+(n/2))))/(((1-a x))^n))dx

Program code:

Int[x_^m_.*(c_+d_.*x_^2)^p_.*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  c^p*Int[x^m*(1-a^2*x^2)^(p+n/2)/(1-a*x)^n,x] /;
FreeQ[{a,c,d,m,p},x] && EqQ[a^2*c+d,0] && (IntegerQ[p] || GtQ[c,0]) && ILtQ[(n-1)/2,0] && Not[IntegerQ[p-n/2]]

2:  ∫(x^m) (((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ (p∈ℤ ∨ c>0)

Derivation: Algebraic simplification

Basis: If  (a^2) c+d==0 ∧ (p∈ℤ ∨ c>0), then (((c+d (x^2)))^p)==(c^p) (((1-a x))^p) (((1+a x))^p)

Basis: (e^(n ArcTanh[z]))==((((1+z))^(n/2))/(((1-z))^(n/2)))

Rule: If  (a^2) c+d==0 ∧ (p∈ℤ ∨ c>0), then

∫(x^m) (((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (c^p)∫(x^m) (((1-a x))^p)(((1+a x))^p)  ((((1+a x))^(n/2))/(((1-a x))^(n/2)))dx  ⟶  (c^p)∫(x^m) (((1-a x))^(p-(n/2))) (((1+a x))^(p+(n/2)))dx

Program code:

Int[x_^m_.*(c_+d_.*x_^2)^p_.*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  c^p*Int[x^m*(1-a*x)^(p-n/2)*(1+a*x)^(p+n/2),x] /;
FreeQ[{a,c,d,m,n,p},x] && EqQ[a^2*c+d,0] && (IntegerQ[p] || GtQ[c,0])

4.  ∫(x^m) (((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0)

1.  ∫(x^m) (((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∈ℤ

1:  ∫(x^m) (((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∈(SuperPlus[ℤ])

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1+z))^n)/(((1-(z^2)))^(n/2)))

Basis: If  (a^2) c+d==0 ∧ (n/2)∈ℤ, then (((1-(a^2) (x^2)))^(-n/2))==(c^(n/2)) (((c+d (x^2)))^(-n/2))

Rule: If  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∈(SuperPlus[ℤ]), then

∫(x^m) (((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  ∫(x^m) (((c+d (x^2)))^p) ((((1+a x))^n)/(((1-(a^2)(x^2)))^(n/2)))dx  ⟶  (c^(n/2))∫(x^m) (((c+d (x^2)))^(p-(n/2)))(((1+a x))^n)dx

Program code:

Int[x_^m_.*(c_+d_.*x_^2)^p_.*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  c^(n/2)*Int[x^m*(c+d*x^2)^(p-n/2)*(1+a*x)^n,x] /;
FreeQ[{a,c,d,m,p},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[p] || GtQ[c,0]] && IGtQ[n/2,0]

2:  ∫(x^m) (((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∈(SuperMinus[ℤ])

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1-(z^2)))^(n/2))/(((1-z))^n))

Basis: If  (a^2) c+d==0 ∧ (n/2)∈ℤ, then (((1-(a^2) (x^2)))^(n/2))==(1/(c^(n/2))) (((c+d (x^2)))^(n/2))

Rule: If  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∈(SuperMinus[ℤ]), then

∫(x^m) (((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  ∫(x^m) (((c+d (x^2)))^p) ((((1-(a^2)(x^2)))^(n/2))/(((1-a x))^n))dx  ⟶  (1/(c^(n/2)))∫(((x^m) (((c+d (x^2)))^(p+(n/2))))/(((1-a x))^n))dx

Program code:

Int[x_^m_.*(c_+d_.*x_^2)^p_.*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  1/c^(n/2)*Int[x^m*(c+d*x^2)^(p+n/2)/(1-a*x)^n,x] /;
FreeQ[{a,c,d,m,p},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[p] || GtQ[c,0]] && ILtQ[n/2,0]

2:  ∫(x^m) (((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (a^2) c+d==0, then (∂_x)((((c+d (x^2)))^p)/(((1-(a^2)(x^2)))^p))==0

Rule: If  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∉ℤ, then

∫(x^m) (((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (((c^(IntPart[p]))(((c+d (x^2)))^(FracPart[p])))/(((1-(a^2)(x^2)))^(FracPart[p])))∫(x^m) (((1-(a^2)(x^2)))^p) (e^(n ArcTanh[a x]))dx

Program code:

Int[x_^m_.*(c_+d_.*x_^2)^p_*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  c^IntPart[p]*(c+d*x^2)^FracPart[p]/(1-a^2*x^2)^FracPart[p]*Int[x^m*(1-a^2*x^2)^p*E^(n*ArcTanh[a*x]),x] /;
FreeQ[{a,c,d,m,n,p},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[p] || GtQ[c,0]] && Not[IntegerQ[n/2]]

3.  ∫u(((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0

1:  ∫u(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ (p∈ℤ ∨ c>0)

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1+z))^(n/2))/(((1-z))^(n/2)))

Basis: (((1-(z^2)))^p)==(((1-z))^p)(((1+z))^p)

Rule: If  (a^2) c+d==0 ∧ (p∈ℤ ∨ c>0), then

∫u(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (c^p)∫u(((1-a x))^p)(((1+a x))^p)  ((((1+a x))^(n/2))/(((1-a x))^(n/2)))dx  ⟶  (c^p)∫u(((1-a x))^(p-(n/2)))(((1+a x))^(p+(n/2)))dx

Program code:

Int[u_*(c_+d_.*x_^2)^p_.*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  c^p*Int[u*(1-a*x)^(p-n/2)*(1+a*x)^(p+n/2),x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[a^2*c+d,0] && (IntegerQ[p] || GtQ[c,0])

2.  ∫u(((c+d (x^2)))^p)(e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0)

1:  ∫u(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∈ℤ

Derivation: Piecewise constant extraction

Basis: If  (a^2) c+d==0, then (∂_x)((((c+d (x^2)))^p)/((((1-a x))^p) (((1+a x))^p)))==0

Basis: (e^(n ArcTanh[z]))==((((1+z))^(n/2))/(((1-z))^(n/2)))

Rule: If  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∈ℤ, then

∫u(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (((c^(IntPart[p])) (((c+d (x^2)))^(FracPart[p])))/((((1-a x))^(FracPart[p])) (((1+a x))^(FracPart[p]))))∫u(((1-a x))^(p-(n/2)))(((1+a x))^(p+(n/2))) dx

Program code:

Int[u_*(c_+d_.*x_^2)^p_*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  c^IntPart[p]*(c+d*x^2)^FracPart[p]/((1-a*x)^FracPart[p]*(1+a*x)^FracPart[p])*
    Int[u*(1-a*x)^(p-n/2)*(1+a*x)^(p+n/2),x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[p] || GtQ[c,0]] && IntegerQ[n/2]

2:  ∫u(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  when  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (a^2) c+d==0, then (∂_x)((((c+d (x^2)))^p)/(((1-(a^2)(x^2)))^p))==0

Rule: If  (a^2) c+d==0 ∧ ¬(p∈ℤ ∨ c>0) ∧ (n/2)∉ℤ, then

∫u(((c+d (x^2)))^p) (e^(n ArcTanh[a x]))dx  ⟶  (((c^(IntPart[p])) (((c+d (x^2)))^(FracPart[p])))/(((1-(a^2)(x^2)))^(FracPart[p])))∫u(((1-(a^2)(x^2)))^p) (e^(n ArcTanh[a x]))dx

Program code:

Int[u_*(c_+d_.*x_^2)^p_*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  c^IntPart[p]*(c+d*x^2)^FracPart[p]/(1-a^2*x^2)^FracPart[p]*Int[u*(1-a^2*x^2)^p*E^(n*ArcTanh[a*x]),x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[p] || GtQ[c,0]] && Not[IntegerQ[n/2]]

5.  ∫u(((c+(d/(x^2))))^p) (e^(n ArcTanh[a x]))dx  when  c+(a^2)d==0

1:  ∫u(((c+(d/(x^2))))^p) (e^(n ArcTanh[a x]))dx  when  c+(a^2)d==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  c+(a^2)d==0 ∧ p∈ℤ, then (((c+(d/(x^2))))^p)==((d^p)/(x^(2 p)))(((1-(a^2)(x^2)))^p)

Rule: If  c+(a^2)d==0 ∧ p∈ℤ, then

∫u(((c+(d/(x^2))))^p) (e^(n ArcTanh[a x]))dx  ⟶  (d^p)∫(u/(x^(2 p)))(((1-(a^2)(x^2)))^p) (e^(n ArcTanh[a x]))dx

Program code:

Int[u_.*(c_+d_./x_^2)^p_.*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  d^p*Int[u/x^(2*p)*(1-a^2*x^2)^p*E^(n*ArcTanh[a*x]),x] /;
FreeQ[{a,c,d,n},x] && EqQ[c+a^2*d,0] && IntegerQ[p]

2.  ∫u(((c+(d/(x^2))))^p) (e^(n ArcTanh[a x]))dx  when  c+(a^2)d==0 ∧ p∉ℤ

1.  ∫u(((c+(d/(x^2))))^p) (e^(n ArcTanh[a x]))dx  when  c+(a^2)d==0 ∧ p∉ℤ ∧ (n/2)∈ℤ

1:  ∫u(((c+(d/(x^2))))^p) (e^(n ArcTanh[a x]))dx  when  c+(a^2)d==0 ∧ p∉ℤ ∧ (n/2)∈ℤ ∧ c>0

Derivation: Algebraic simplification

Basis: (((1-(z^2)))^p)==(((1-z))^p)(((1+z))^p)

Rule: If  c+(a^2)d==0 ∧ p∉ℤ ∧ (n/2)∈ℤ ∧ c>0, then

∫u(((c+(d/(x^2))))^p) (e^(n ArcTanh[a x]))dx  ⟶  (c^p)∫u(((1-((1 )/((a^2)(x^2)))))^p) (e^(n ArcTanh[a x]))dx  ⟶  (c^p)∫u(((1-(1/(a x))))^p) (((1+(1/(a x))))^p)(e^(n ArcTanh[a x]))dx

Program code:

Int[u_.*(c_+d_./x_^2)^p_*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  c^p*Int[u*(1-1/(a*x))^p*(1+1/(a*x))^p*E^(n*ArcTanh[a*x]),x] /;
FreeQ[{a,c,d,p},x] && EqQ[c+a^2*d,0] && Not[IntegerQ[p]] && IntegerQ[n/2] && GtQ[c,0]

2:  ∫u(((c+(d/(x^2))))^p) (e^(n ArcTanh[a x]))dx  when  c+(a^2)d==0 ∧ p∉ℤ ∧ (n/2)∈ℤ ∧ c≯0

Derivation: Piecewise constant extraction

Basis: If  c+(a^2)d==0, then (∂_x)(((x^(2p))(((c+(d/(x^2))))^p))/((((1-a x))^p)(((1+a x))^p)))==0

Rule: If  c+(a^2)d==0 ∧ p∉ℤ ∧ (n/2)∈ℤ ∧ c≯0, then

∫u(((c+(d/(x^2))))^p) (e^(n ArcTanh[a x]))dx  ⟶  (((x^(2p))(((c+(d/(x^2))))^p))/((((1-a x))^p)(((1+a x))^p)))∫(u/(x^(2 p)))(((1-a x))^p)(((1+a x))^p) (e^(n ArcTanh[a x]))dx

Program code:

Int[u_.*(c_+d_./x_^2)^p_*E^(n_*ArcTanh[a_.*x_]),x_Symbol] :=
  x^(2*p)*(c+d/x^2)^p/((1-a*x)^p*(1+a*x)^p)*Int[u/x^(2*p)*(1-a*x)^p*(1+a*x)^p*E^(n*ArcTanh[a*x]),x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[c+a^2*d,0] && Not[IntegerQ[p]] && IntegerQ[n/2] && Not[GtQ[c,0]]

2:  ∫u(((c+(d/(x^2))))^p) (e^(n ArcTanh[a x]))dx  when  c+(a^2)d==0 ∧ p∉ℤ ∧ (n/2)∉ℤ

Derivation: Piecewise constant extraction

Basis: If c+(a^2)d==0, then (∂_x)(((x^(2p))(((c+(d/(x^2))))^p))/(((1-(a^2)(x^2)))^p))==0

Rule: If c+(a^2)d==0 ∧ p∉ℤ ∧ (n/2)∉ℤ, then

∫u(((c+(d/(x^2))))^p) (e^(n ArcTanh[a x]))dx  ⟶  (((x^(2p))(((c+(d/(x^2))))^p))/(((1-(a^2)(x^2)))^p))∫(u/(x^(2 p)))(((1-(a^2)(x^2)))^p) (e^(n ArcTanh[a x]))dx

Program code:

Int[u_.*(c_+d_./x_^2)^p_*E^(n_.*ArcTanh[a_.*x_]),x_Symbol] :=
  x^(2*p)*(c+d/x^2)^p/(1+c*x^2/d)^p*Int[u/x^(2*p)*(1+c*x^2/d)^p*E^(n*ArcTanh[a*x]),x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[c+a^2*d,0] && Not[IntegerQ[p]] && Not[IntegerQ[n/2]]

2.  ∫u (e^(n ArcTanh[a+b x]))dx

1:  ∫(e^(n ArcTanh[c (a+b x)]))dx

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1+z))^(n/2))/(((1-z))^(n/2)))

Rule:

∫(e^(n ArcTanh[c (a+b x)]))dx  ⟶  ∫((((1+a c+b c x))^(n/2))/(((1-a c-b c x))^(n/2)))dx

Program code:

Int[E^(n_.*ArcTanh[c_.*(a_+b_.*x_)]),x_Symbol] :=
  Int[(1+a*c+b*c*x)^(n/2)/(1-a*c-b*c*x)^(n/2),x] /;
FreeQ[{a,b,c,n},x]

2.  ∫(((d+e x))^m)(e^(n ArcTanh[c (a+b x)]))dx

1:  ∫(x^m) (e^(n ArcTanh[c (a+b x)]))dx  when  m∈(SuperMinus[ℤ])∧ -1<n<1

Derivation: Algebraic simplification and integration by substitution

Basis: (e^(n ArcTanh[z]))==((((1+z))^(n/2))/(((1-z))^(n/2)))

Basis: If  m∈ℤ ∧ -1<n<1 , then (x^m)((((1+c (a+b x)))^(n/2))/(((1-c (a+b x)))^(n/2)))==(4/(n (b^(m+1))(c^(m+1))))Subst[(((x^(2/n)) (((-1-a c+(1-a c) (x^(2/n))))^m))/(((1+(x^(2/n))))^(m+2))),x,((((1+c (a+b x)))^(n/2))/(((1-c (a+b x)))^(n/2)))](∂_x)((((1+c (a+b x)))^(n/2))/(((1-c (a+b x)))^(n/2)))

Note: There should be an algebraic substitution rule that makes this rule redundant.

Rule: If  m∈(SuperMinus[ℤ])∧ -1<n<1 , then

∫(x^m) (e^(n ArcTanh[c (a+b x)]))dx  ⟶  ∫(x^m)((((1+c (a+b x)))^(n/2))/(((1-c (a+b x)))^(n/2)))dx                                                                                                
                                                                            ⟶  (4/(n (b^(m+1))(c^(m+1))))Subst[∫(((x^(2/n)) (((-1-a c+(1-a c) (x^(2/n))))^m))/(((1+(x^(2/n))))^(m+2)))dx,x,((((1+c (a+b x)))^(n/2))/(((1-c (a+b x)))^(n/2)))]

Program code:

Int[x_^m_*E^(n_*ArcTanh[c_.*(a_+b_.*x_)]),x_Symbol] :=
  4/(n*b^(m+1)*c^(m+1))*
    Subst[Int[x^(2/n)*(-1-a*c+(1-a*c)*x^(2/n))^m/(1+x^(2/n))^(m+2),x],x,(1+c*(a+b*x))^(n/2)/(1-c*(a+b*x))^(n/2)] /;
FreeQ[{a,b,c},x] && ILtQ[m,0] && LtQ[-1,n,1]

2:  ∫(((d+e x))^m)(e^(n ArcTanh[c (a+b x)]))dx

Derivation: Algebraic simplification

Basis: (e^(n ArcTanh[z]))==((((1+z))^(n/2))/(((1-z))^(n/2)))

Rule:

∫(((d+e x))^m)(e^(n ArcTanh[c (a+b x)]))dx  ⟶  ∫(((d+e x))^m)((((1+a c+b c x))^(n/2))/(((1-a c-b c x))^(n/2)))dx

Program code:

Int[(d_.+e_.*x_)^m_.*E^(n_.*ArcTanh[c_.*(a_+b_.*x_)]),x_Symbol] :=
  Int[(d+e*x)^m*(1+a*c+b*c*x)^(n/2)/(1-a*c-b*c*x)^(n/2),x] /;
FreeQ[{a,b,c,d,e,m,n},x]

3.  ∫u(((c+d x+e (x^2)))^p)(e^(n ArcTanh[a+b x]))dx  when  b d==2 a e ∧ (b^2) c+e(1-(a^2))==0

1:  ∫u(((c+d x+e (x^2)))^p) (e^(n ArcTanh[a+b x]))dx  when  b d==2 a e ∧ (b^2) c+e(1-(a^2))==0 ∧ (p∈ℤ ∨ (c/(1-(a^2)))>0)

Derivation: Algebraic simplification

Basis: If  b d==2 a e ∧ (b^2) c+e(1-(a^2))==0, then c+d x+e (x^2)==(c/(1-(a^2)))(1-(((a+b x))^2))

Basis: (((1-(z^2)))^p)==(((1-z))^p)(((1+z))^p)

Basis: (e^(n ArcTanh[z]))==((((1+z))^(n/2))/(((1-z))^(n/2)))

Rule: If  b d==2 a e ∧ (b^2) c+e(1-(a^2))==0 ∧ (p∈ℤ ∨ (c/(1-(a^2)))>0), then

∫u(((c+d x+e (x^2)))^p) (e^(n ArcTanh[a+b x]))dx  ⟶  ((((c/(1-(a^2)))))^p)∫u(((1-(((a+b x))^2)))^p) (e^(n ArcTanh[a+b x]))dx                                          
                                                               ⟶  ((((c/(1-(a^2)))))^p)∫u(((1-a-b x))^p)(((1+a+b x))^p)  ((((1+a+b x))^(n/2))/(((1-a-b x))^(n/2)))dx
                                            ⟶  ((((c/(1-(a^2)))))^p)∫u(((1-a-b x))^(p-n/2))(((1+a+b x))^(p+n/2))dx

Program code:

Int[u_.*(c_+d_.*x_+e_.*x_^2)^p_.*E^(n_.*ArcTanh[a_+b_.*x_]),x_Symbol] :=
  (c/(1-a^2))^p*Int[u*(1-a-b*x)^(p-n/2)*(1+a+b*x)^(p+n/2),x] /;
FreeQ[{a,b,c,d,e,n,p},x] && EqQ[b*d-2*a*e,0] && EqQ[b^2*c+e(1-a^2),0] && (IntegerQ[p] || GtQ[c/(1-a^2),0])

2:  ∫u(((c+d x+e (x^2)))^p) (e^(n ArcTanh[a+b x]))dx  when  b d==2 a e ∧ (b^2) c+e(1-(a^2))==0 ∧ ¬(p∈ℤ ∨ (c/(1-(a^2)))>0)

Derivation: Piecewise constant extraction

Basis: If  b d==2 a e ∧ (b^2) c+e(1-(a^2))==0, then (∂_x)((((c+d x+e (x^2)))^p)/(((1-(a^2)-2 a b x-(b^2) (x^2)))^p))==0

Rule: If  b d==2 a e ∧ (b^2) c+e(1-(a^2))==0 ∧ ¬(p∈ℤ ∨ (c/(1-(a^2)))>0), then

∫u(((c+d x+e (x^2)))^p) (e^(n ArcTanh[a+b x]))dx  ⟶  ((((c+d x+e (x^2)))^p)/(((1-(a^2)-2 a b x-(b^2) (x^2)))^p))∫u(((1-(a^2)-2 a b x-(b^2) (x^2)))^p) (e^(n ArcTanh[a+b x]))dx

Program code:

Int[u_.*(c_+d_.*x_+e_.*x_^2)^p_.*E^(n_.*ArcTanh[a_+b_.*x_]),x_Symbol] :=
  (c+d*x+e*x^2)^p/(1-a^2-2*a*b*x-b^2*x^2)^p*Int[u*(1-a^2-2*a*b*x-b^2*x^2)^p*E^(n*ArcTanh[a*x]),x] /;
FreeQ[{a,b,c,d,e,n,p},x] && EqQ[b*d-2*a*e,0] && EqQ[b^2*c+e(1-a^2),0] && Not[IntegerQ[p] || GtQ[c/(1-a^2),0]]

3:  ∫u (e^(n ArcTanh[(c/(a+b x))]))dx

Derivation: Algebraic simplification

Basis: ArcTanh[z]==ArcCoth[(1/z)]

Rule:

∫u (e^(n ArcTanh[(c/(a+b x))]))dx  ⟶  ∫u (e^(n ArcCoth[(a/c)+((b x)/c)]))dx

Program code:

Int[u_.*E^(n_.*ArcTanh[c_./(a_.+b_.*x_)]),x_Symbol] :=
  Int[u*E^(n*ArcCoth[a/c+b*x/c]),x] /;
FreeQ[{a,b,c,n},x]

Rules for integrands involving exponentials of inverse hyperbolic cotangents

1.  ∫u (e^(n ArcCoth[a x]))dx

1:  ∫u (e^(n ArcCoth[a x]))dx  when  (n/2)∈ℤ

Derivation: Algebraic simplification

Basis: If (n/2)∈ℤ, then (e^(n ArcCoth[z]))==(((-1))^(n/2))(e^(n ArcTanh[z]))

Rule: If (n/2)∈ℤ, then

∫u (e^(n ArcCoth[a x]))dx  ⟶  (((-1))^(n/2))∫u (e^(n ArcTanh[a x]))dx

Program code:

Int[u_.*E^(n_*ArcCoth[a_.*x_]),x_Symbol] :=
  (-1)^(n/2)*Int[u*E^(n*ArcTanh[a*x]),x] /;
FreeQ[a,x] && IntegerQ[n/2]

2.  ∫u (e^(n ArcCoth[a x]))dx  when  (n/2)∉ℤ

1.  ∫(x^m) (e^(n ArcCoth[a x]))dx  when  (n/2)∉ℤ

1.  ∫(x^m) (e^(n ArcCoth[a x]))dx  when  (n/2)∉ℤ ∧ m∈ℤ

1:  ∫(x^m)(e^(n ArcCoth[a x]))dx  when  ((n-1)/2)∈ℤ ∧ m∈ℤ

Derivation: Algebraic simplification and integration by substitution

Basis: (e^(n ArcCoth[z]))==((((1+(1/z)))^((n+1)/2))/((((1-(1/z)))^((n-1)/2))(Sqrt[1-(1/(z^2))])))

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If ((n-1)/2)∈ℤ ∧ m∈ℤ, then

∫(x^m)(e^(n ArcCoth[a x]))dx  ⟶  ∫((((1+(1/(a x))))^((n+1)/2))/(((((1/x)))^m)(((1-(1/(a x))))^((n-1)/2))(Sqrt[1-(1/((a^2) (x^2)))])))dx  ⟶  -Subst[∫((((1+(x/a)))^((n+1)/2))/((x^(m+2))(((1-(x/a)))^((n-1)/2))(Sqrt[1-((x^2)/(a^2))])))dx,x,(1/x)]

Program code:

Int[E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -Subst[Int[(1+x/a)^((n+1)/2)/(x^2*(1-x/a)^((n-1)/2)*Sqrt[1-x^2/a^2]),x],x,1/x] /;
FreeQ[a,x] && IntegerQ[(n-1)/2]

Int[x_^m_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -Subst[Int[(1+x/a)^((n+1)/2)/(x^(m+2)*(1-x/a)^((n-1)/2)*Sqrt[1-x^2/a^2]),x],x,1/x] /;
FreeQ[a,x] && IntegerQ[(n-1)/2] && IntegerQ[m]

2:  ∫(x^m)(e^(n ArcCoth[a x]))dx  when  n∉ℤ ∧ m∈ℤ

Derivation: Algebraic simplification and integration by substitution

Basis: (e^(n ArcCoth[z]))==((((1+(1/z)))^(n/2))/(((1-(1/z)))^(n/2)))

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If n∉ℤ ∧ m∈ℤ, then

∫(x^m)(e^(n ArcCoth[a x]))dx  ⟶  ∫((((1+(1/(a x))))^(n/2))/(((((1/x)))^m)(((1-(1/(a x))))^(n/2))))dx  ⟶  -Subst[∫((((1+(x/a)))^(n/2))/((x^(m+2))(((1-(x/a)))^(n/2))))dx,x,(1/x)]

Program code:

Int[E^(n_*ArcCoth[a_.*x_]),x_Symbol] :=
  -Subst[Int[(1+x/a)^(n/2)/(x^2*(1-x/a)^(n/2)),x],x,1/x] /;
FreeQ[{a,n},x] && Not[IntegerQ[n]]

Int[x_^m_.*E^(n_*ArcCoth[a_.*x_]),x_Symbol] :=
  -Subst[Int[(1+x/a)^(n/2)/(x^(m+2)*(1-x/a)^(n/2)),x],x,1/x] /;
FreeQ[{a,n},x] && Not[IntegerQ[n]] && IntegerQ[m]

2.  ∫(x^m) (e^(n ArcCoth[a x]))dx  when  (n/2)∉ℤ ∧ m∉ℤ

1:  ∫(x^m)(e^(n ArcCoth[a x]))dx  when  ((n-1)/2)∈ℤ ∧ m∉ℤ

Derivation: Algebraic simplification, piecewise constant extraction and integration by substitution!

Basis: (e^(n ArcCoth[z]))==((((1+(1/z)))^((n+1)/2))/((((1-(1/z)))^((n-1)/2))(Sqrt[1-(1/(z^2))])))

Basis: (∂_x)((x^m) ((((1/x)))^m))==0

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If ((n-1)/2)∈ℤ ∧ m∉ℤ, then

∫(x^m)(e^(n ArcCoth[a x]))dx  ⟶  (x^m)((((1/x)))^m)∫((((1+(1/(a x))))^((n+1)/2))/(((((1/x)))^m)(((1-(1/(a x))))^((n-1)/2))(Sqrt[1-(1/((a^2) (x^2)))])))dx  ⟶  -(x^m)((((1/x)))^m) Subst[∫((((1+(x/a)))^((n+1)/2))/((x^(m+2))(((1-(x/a)))^((n-1)/2))(Sqrt[1-((x^2)/(a^2))])))dx,x,(1/x)]

Program code:

Int[x_^m_*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -x^m*(1/x)^m*Subst[Int[(1+x/a)^((n+1)/2)/(x^(m+2)*(1-x/a)^((n-1)/2)*Sqrt[1-x^2/a^2]),x],x,1/x] /;
FreeQ[{a,m},x] && IntegerQ[(n-1)/2] && Not[IntegerQ[m]]

2:  ∫(x^m)(e^(n ArcCoth[a x]))dx  when  n∉ℤ ∧ m∉ℤ

Derivation: Algebraic simplification, piecewise constant extraction and integration by substitution!

Basis: (e^(n ArcCoth[z]))==((((1+(1/z)))^(n/2))/(((1-(1/z)))^(n/2)))

Basis: (∂_x)((x^m) ((((1/x)))^m))==0

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If n∉ℤ ∧ m∉ℤ, then

∫(x^m)(e^(n ArcCoth[a x]))dx  ⟶  (x^m)((((1/x)))^m)∫((((1+(1/(a x))))^(n/2))/(((((1/x)))^m)(((1-(1/(a x))))^(n/2))))dx  ⟶  -(x^m)((((1/x)))^m) Subst[∫((((1+(x/a)))^(n/2))/((x^(m+2))(((1-(x/a)))^(n/2))))dx,x,(1/x)]

Program code:

Int[x_^m_*E^(n_*ArcCoth[a_.*x_]),x_Symbol] :=
  -x^m*(1/x)^m*Subst[Int[(1+x/a)^(n/2)/(x^(m+2)*(1-x/a)^(n/2)),x],x,1/x] /;
FreeQ[{a,m,n},x] && Not[IntegerQ[n]] && Not[IntegerQ[m]]

2.  ∫u(((c+d x))^p)(e^(n ArcCoth[a x]))dx  when  (a^2) (c^2)-(d^2)==0 ∧ (n/2)∉ℤ

1:  ∫(((c+d x))^p)(e^(n ArcCoth[a x]))dx  when  a c+d==0 ∧ p==(n/2)∉ℤ

Rule: If  a c+d==0 ∧ p==(n/2)∉ℤ, then

∫(((c+d x))^p)(e^(n ArcCoth[a x]))dx  ⟶  (((1+a x) (((c+d x))^p) (e^(n ArcCoth[a x])))/(a (p+1)))

Program code:

Int[(c_+d_.*x_)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  (1+a*x)*(c+d*x)^p*E^(n*ArcCoth[a*x])/(a*(p+1)) /;
FreeQ[{a,c,d,n,p},x] && EqQ[a*c+d,0] && EqQ[p,n/2] && Not[IntegerQ[n/2]]

x.  ∫(x^m)(((c+d x))^p)(e^(n ArcCoth[a x]))dx  when  a c+d==0 ∧ ((n-1)/2)∈ℤ ∧ m∈ℤ

1:  ∫(x^m)(((c+d x))^p) (e^(n ArcCoth[a x]))dx  when  a c+d==0 ∧ ((n-1)/2)∈ℤ ∧ m∈ℤ ∧ p∈ℤ

Derivation: Algebraic simplification and integration by substitution

Basis: If  n∈ℤ, then (e^(n ArcCoth[a x]))==(((-a))^n) (c^n) (x^n) (((c-a c x))^(-n)) (((1-(1/((a^2) (x^2)))))^(n/2))

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If  a c+d==0 ∧ ((n-1)/2)∈ℤ ∧ m∈ℤ ∧ p∈ℤ, then

∫(x^m)(((c+d x))^p) (e^(n ArcCoth[a x]))dx  ⟶  (((-a))^n) (c^n)∫(x^(m+n))(((c+d x))^(p-n)) (((1-(1/((a^2) (x^2)))))^(n/2))dx  ⟶  -(((-a))^n) (c^n)Subst[∫(((((d+c x))^(p-n)) (((1-((x^2)/(a^2))))^(n/2)))/(x^(m+p+2)))dx,x,(1/x)]

Program code:

(* Int[(c_+d_.*x_)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -(-a)^n*c^n*Subst[Int[(d+c*x)^(p-n)*(1-x^2/a^2)^(n/2)/x^(p+2),x],x,1/x] /;
FreeQ[{a,c,d},x] && EqQ[a*c+d,0] && IntegerQ[(n-1)/2] && IntegerQ[p] *)

(* Int[x_^m_.*(c_+d_.*x_)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -(-a)^n*c^n*Subst[Int[(d+c*x)^(p-n)*(1-x^2/a^2)^(n/2)/x^(m+p+2),x],x,1/x] /;
FreeQ[{a,c,d},x] && EqQ[a*c+d,0] && IntegerQ[(n-1)/2] && IntegerQ[m] && IntegerQ[p] *)

2:  ∫(x^m)(((c+d x))^p) (e^(n ArcCoth[a x]))dx  when  a c+d==0 ∧ ((n-1)/2)∈ℤ ∧ m∈ℤ ∧ p-(1/2)∈ℤ

Derivation: Algebraic simplification, integration by substitution and piecewise constant extraction!

Basis: If  n∈ℤ, then (((c-a c x))^n) (e^(n ArcCoth[a x]))==(((-a))^n) (c^n) (x^n)(((1-(1/((a^2) (x^2)))))^(n/2))

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Basis: (∂_x)((Sqrt[c+d x])/((Sqrt[x])(Sqrt[d+(c/x)])))==0

Rule: If  a c+d==0 ∧ ((n-1)/2)∈ℤ ∧ m∈ℤ ∧ p-(1/2)∈ℤ, then

∫(x^m)(((c+d x))^p) (e^(n ArcCoth[a x]))dx  ⟶  (((-a))^n) (c^n)∫(x^(m+n))(((c+d x))^(p-n)) (((1-(1/((a^2) (x^2)))))^(n/2))dx

  ⟶  (((((-a))^n) (c^n) (Sqrt[c+d x]))/((Sqrt[x])(Sqrt[d+(c/x)])))∫(((((d+(c/x)))^(p-n)) (((1-(1/((a^2) (x^2)))))^(n/2)))/((((1/x)))^(m+p)))dx  ⟶  -(((((-a))^n) (c^n) (Sqrt[c+d x]))/((Sqrt[x])(Sqrt[d+(c/x)])))Subst[∫(((((d+c x))^(p-n)) (((1-((x^2)/(a^2))))^(n/2)))/(x^(m+p+2)))dx,x,(1/x)]

Program code:

(* Int[(c_+d_.*x_)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -(-a)^n*c^n*Sqrt[c+d*x]/(Sqrt[x]*Sqrt[d+c/x])*Subst[Int[(d+c*x)^(p-n)*(1-x^2/a^2)^(n/2)/x^(p+2),x],x,1/x] /;
FreeQ[{a,c,d},x] && EqQ[a*c+d,0] && IntegerQ[(n-1)/2] && IntegerQ[p-1/2] *)

(* Int[x_^m_.*(c_+d_.*x_)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -(-a)^n*c^n*Sqrt[c+d*x]/(Sqrt[x]*Sqrt[d+c/x])*Subst[Int[(d+c*x)^(p-n)*(1-x^2/a^2)^(n/2)/x^(m+p+2),x],x,1/x] /;
FreeQ[{a,c,d},x] && EqQ[a*c+d,0] && IntegerQ[(n-1)/2] && IntegerQ[m] && IntegerQ[p-1/2] *)

1:  ∫u(((c+d x))^p)(e^(n ArcCoth[a x]))dx  when  (a^2) (c^2)-(d^2)==0 ∧ (n/2)∉ℤ ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If p∈ℤ, then (((c+d x))^p)==(d^p)(x^p)(((1+(c/(d x))))^p)

Rule: If  (a^2) (c^2)-(d^2)==0 ∧ (n/2)∉ℤ ∧ p∈ℤ, then

∫u(((c+d x))^p)(e^(n ArcCoth[a x]))dx  ⟶  (d^p)∫u (x^p)(((1+(c/(d x))))^p)(e^(n ArcCoth[a x]))dx

Program code:

Int[u_.*(c_+d_.*x_)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  d^p*Int[u*x^p*(1+c/(d*x))^p*E^(n*ArcCoth[a*x]),x] /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c^2-d^2,0] && Not[IntegerQ[n/2]] && IntegerQ[p]

2:  ∫u(((c+d x))^p) (e^(n ArcCoth[a x]))dx  when  (a^2) (c^2)-(d^2)==0 ∧ (n/2)∉ℤ ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((c+d x))^p)/((x^p)(((1+(c/(d x))))^p)))==0

Rule: If  (a^2) (c^2)-(d^2)==0 ∧ (n/2)∉ℤ ∧ p∉ℤ, then

∫u(((c+d x))^p) (e^(n ArcCoth[a x]))dx  ⟶  ((((c+d x))^p)/((x^p)(((1+(c/(d x))))^p)))∫u (x^p)(((1+(c/(d x))))^p) (e^(n ArcCoth[a x]))dx

Program code:

Int[u_.*(c_+d_.*x_)^p_*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  (c+d*x)^p/(x^p*(1+c/(d*x))^p)*Int[u*x^p*(1+c/(d*x))^p*E^(n*ArcCoth[a*x]),x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[a^2*c^2-d^2,0] && Not[IntegerQ[n/2]] && Not[IntegerQ[p]]

3.  ∫u(((c+(d/x)))^p) (e^(n ArcCoth[a x]))dx  when  (c^2)-(a^2)(d^2)==0 ∧ (n/2)∉ℤ

1.  ∫(x^m)(((c+(d/x)))^p) (e^(n ArcCoth[a x]))dx  when  (c^2)-(a^2)(d^2)==0 ∧ (n/2)∉ℤ ∧ (p∈ℤ ∨ c>0)

1.  ∫(x^m)(((c+(d/x)))^p) (e^(n ArcCoth[a x]))dx  when  (c^2)-(a^2)(d^2)==0 ∧ (n/2)∉ℤ ∧ (p∈ℤ ∨ c>0) ∧ m∈ℤ

1:  ∫(x^m) (((c+(d/x)))^p) (e^(n ArcCoth[a x]))dx  when  c+a d==0 ∧ ((n-1)/2)∈ℤ ∧ m∈ℤ ∧ (p∈ℤ ∨ p-(n/2)==0 ∨ p-(n/2)-1==0)

Derivation: Algebraic simplification and integration by substitution

Basis: If  c+a d==0 ∧ n∈ℤ, then (((c+(d/x)))^n) (e^(n ArcCoth[a x]))==(c^n) (((1-(1/((a^2) (x^2)))))^(n/2))

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Note: The condition p∈ℤ ∨ p-(n/2)==0 ∨ p-(n/2)-1==0 should be removed when the rules for integrands of the form (((d+e x))^m) (((f+g x))^n) (((a+b x+c (x^2)))^p) when c (d^2)-b d e+a (e^2)==0 are strengthened.

Rule: If  c+a d==0 ∧ ((n-1)/2)∈ℤ ∧ m∈ℤ, then

∫(x^m) (((c+(d/x)))^p) (e^(n ArcCoth[a x]))dx  ⟶  (c^n)∫(((((c+(d/x)))^(p-n)) (((1-(1/((a^2) (x^2)))))^(n/2)))/((((1/x)))^m))dx  ⟶  -(c^n)Subst[∫(((((c+d x))^(p-n)) (((1-((x^2)/(a^2))))^(n/2)))/(x^(m+2)))dx,x,(1/x)]

Program code:

Int[(c_+d_./x_)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -c^n*Subst[Int[(c+d*x)^(p-n)*(1-x^2/a^2)^(n/2)/x^2,x],x,1/x] /;
FreeQ[{a,c,d,p},x] && EqQ[c+a*d,0] && IntegerQ[(n-1)/2] && (IntegerQ[p] || EqQ[p,n/2] || EqQ[p,n/2+1]) && IntegerQ[2*p]

Int[x_^m_.*(c_+d_./x_)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -c^n*Subst[Int[(c+d*x)^(p-n)*(1-x^2/a^2)^(n/2)/x^(m+2),x],x,1/x] /;
FreeQ[{a,c,d,p},x] && EqQ[c+a*d,0] && IntegerQ[(n-1)/2] && IntegerQ[m] && (IntegerQ[p] || EqQ[p,n/2] || EqQ[p,n/2+1] || LtQ[-5,m,-1]) && IntegerQ[2*p]

2:  ∫(x^m)(((c+(d/x)))^p) (e^(n ArcCoth[a x]))dx  when  (c^2)-(a^2)(d^2)==0 ∧ (n/2)∉ℤ ∧ (p∈ℤ ∨ c>0) ∧ m∈ℤ

Derivation: Algebraic simplification and integration by substitution

Basis: (e^(n ArcCoth[z]))==((((1+(1/z)))^(n/2))/(((1-(1/z)))^(n/2)))

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Note: Since (c^2)-(a^2)(d^2)==0, the factor (((1+((d x)/c)))^p) will combine with the factor (((1+(x/a)))^(n/2)) or (((1-(x/a)))^(-n/2)).

Rule: If  (c^2)-(a^2)(d^2)==0 ∧ (n/2)∉ℤ ∧ (p∈ℤ ∨ c>0) ∧ m∈ℤ, then

∫(x^m)(((c+(d/x)))^p) (e^(n ArcCoth[a x]))dx  ⟶  (c^p)∫(1/((((1/x)))^m))(((1+(d/(c x))))^p)((((1+(1/(a x))))^(n/2))/(((1-(1/(a x))))^(n/2)))dx  ⟶  -(c^p)Subst[∫(((((1+((d x)/c)))^p)(((1+(x/a)))^(n/2)))/((x^(m+2))(((1-(x/a)))^(n/2))))dx,x,(1/x)]

Program code:

Int[(c_+d_./x_)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -c^p*Subst[Int[(1+d*x/c)^p*(1+x/a)^(n/2)/(x^2*(1-x/a)^(n/2)),x],x,1/x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[c^2-a^2*d^2,0] && Not[IntegerQ[n/2]] && (IntegerQ[p] || GtQ[c,0])

Int[x_^m_.*(c_+d_./x_)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -c^p*Subst[Int[(1+d*x/c)^p*(1+x/a)^(n/2)/(x^(m+2)*(1-x/a)^(n/2)),x],x,1/x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[c^2-a^2*d^2,0] && Not[IntegerQ[n/2]] && (IntegerQ[p] || GtQ[c,0]) && IntegerQ[m]

2:  ∫(x^m)(((c+(d/x)))^p) (e^(n ArcCoth[a x]))dx  when  (c^2)-(a^2)(d^2)==0 ∧ (n/2)∉ℤ ∧ (p∈ℤ ∨ c>0) ∧ m∉ℤ

Derivation: Algebraic simplification, piecewise constant extraction and integration by substitution

Basis: (e^(n ArcCoth[z]))==((((1+(1/z)))^(n/2))/(((1-(1/z)))^(n/2)))

Basis: (∂_x)((x^m) ((((1/x)))^m))==0

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Note: Since (c^2)-(a^2)(d^2)==0, the factor (((1+((d x)/c)))^p) will combine with the factor (((1+(x/a)))^(n/2)) or (((1-(x/a)))^(-n/2)).

Rule: If  (c^2)-(a^2)(d^2)==0 ∧ (n/2)∉ℤ ∧ (p∈ℤ ∨ c>0) ∧ m∉ℤ, then

∫(x^m)(((c+(d/x)))^p) (e^(n ArcCoth[a x]))dx  ⟶  (c^p)(x^m)((((1/x)))^m)∫(1/((((1/x)))^m))(((1+(d/(c x))))^p)((((1+(1/(a x))))^(n/2))/(((1-(1/(a x))))^(n/2)))dx                                      
                                                ⟶  -(c^p)(x^m)((((1/x)))^m)Subst[∫(((((1+((d x)/c)))^p)(((1+(x/a)))^(n/2)))/((x^(m+2))(((1-(x/a)))^(n/2))))dx,x,(1/x)]

Program code:

Int[x_^m_*(c_+d_./x_)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -c^p*x^m*(1/x)^m*Subst[Int[(1+d*x/c)^p*(1+x/a)^(n/2)/(x^(m+2)*(1-x/a)^(n/2)),x],x,1/x] /;
FreeQ[{a,c,d,m,n,p},x] && EqQ[c^2-a^2*d^2,0] && Not[IntegerQ[n/2]] && (IntegerQ[p] || GtQ[c,0]) && Not[IntegerQ[m]]

2:  ∫u(((c+(d/x)))^p)(e^(n ArcCoth[a x]))dx  when  (c^2)-(a^2)(d^2)==0 ∧ (n/2)∉ℤ ∧ ¬(p∈ℤ ∨ c>0)

Derivation: Piecewise constant extraction

Basis: (∂_x)((((c+(d/x)))^p)/(((1+(d/(c x))))^p))==0

Rule: If  (c^2)-(a^2)(d^2)==0 ∧ (n/2)∉ℤ ∧ ¬(p∈ℤ ∨ c>0), then

∫u(((c+(d/x)))^p) (e^(n ArcCoth[a x]))dx  ⟶  ((((c+(d/x)))^p)/(((1+(d/(c x))))^p))∫u(((1+(d/(c x))))^p) (e^(n ArcCoth[a x]))dx

Program code:

Int[u_.*(c_+d_./x_)^p_*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  (c+d/x)^p/(1+d/(c*x))^p*Int[u*(1+d/(c*x))^p*E^(n*ArcCoth[a*x]),x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[c^2-a^2*d^2,0] && Not[IntegerQ[n/2]] && Not[IntegerQ[p] || GtQ[c,0]]

4.  ∫u(((c+d (x^2)))^p)(e^(n ArcCoth[a x]))dx  when  (a^2) c+d==0 ∧ (n/2)∉ℤ

1.  ∫(((c+d (x^2)))^p)(e^(n ArcCoth[a x]))dx  when  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ p≤-1

1:  ∫((e^(n ArcCoth[a x]))/(c+d (x^2)))dx  when  (a^2) c+d==0 ∧ (n/2)∉ℤ

Rule: If  (a^2) c+d==0 ∧ (n/2)∉ℤ, then

∫((e^(n ArcCoth[a x]))/(c+d (x^2)))dx  ⟶  ((e^(n ArcCoth[a x]))/(a c n))

Program code:

Int[E^(n_.*ArcCoth[a_.*x_])/(c_+d_.*x_^2),x_Symbol] :=
  E^(n*ArcCoth[a*x])/(a*c*n) /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[n/2]]

2:  ∫((e^(n ArcCoth[a x]))/(((c+d (x^2)))^(3/2)))dx  when  (a^2) c+d==0 ∧ n∉ℤ

Note: When n is an integer, it is better to transform integrand into algebraic form.

Rule: If  (a^2) c+d==0 ∧ n∉ℤ, then

∫((e^(n ArcCoth[a x]))/(((c+d (x^2)))^(3/2)))dx  ⟶  (((n-a x)(e^(n ArcCoth[a x])))/(a c ((n^2)-1) (Sqrt[c+d (x^2)])))

Program code:

Int[E^(n_*ArcCoth[a_.*x_])/(c_+d_.*x_^2)^(3/2),x_Symbol] :=
  (n-a*x)*E^(n*ArcCoth[a*x])/(a*c*(n^2-1)*Sqrt[c+d*x^2]) /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[n]]

3:  ∫(((c+d (x^2)))^p)(e^(n ArcCoth[a x]))dx  when  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ p<-1 ∧ p≠-(3/2) ∧ (n^2)-4(((p+1))^2)≠0

Rule: If  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ p<-1 ∧ p≠-(3/2) ∧ (n^2)-4(((p+1))^2)≠0, then

∫(((c+d (x^2)))^p)(e^(n ArcCoth[a x]))dx  ⟶  (((n+2 a (p+1) x) (((c+d (x^2)))^(p+1))(e^(n ArcCoth[a x])))/(a c ((n^2)-4 (((p+1))^2))))-((2 (p+1) (2 p+3))/(c((n^2)-4(((p+1))^2))))∫(((c+d (x^2)))^(p+1))(e^(n ArcCoth[a x]))dx

Program code:

Int[(c_+d_.*x_^2)^p_*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  (n+2*a*(p+1)*x)*(c+d*x^2)^(p+1)*E^(n*ArcCoth[a*x])/(a*c*(n^2-4*(p+1)^2)) - 
  2*(p+1)*(2*p+3)/(c*(n^2-4*(p+1)^2))*Int[(c+d*x^2)^(p+1)*E^(n*ArcCoth[a*x]),x] /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[n/2]] && LtQ[p,-1] && NeQ[p,-3/2] && NeQ[n^2-4*(p+1)^2,0] && (IntegerQ[p] || Not[IntegerQ[n]])

2.  ∫(x^m)(((c+d (x^2)))^p)(e^(n ArcCoth[a x]))dx  when  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ m∈ℤ ∧ 0≤m≤-2(p+1)

1.  ∫x(((c+d (x^2)))^p)(e^(n ArcCoth[a x]))dx  when  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ p≤-1

1:  ∫((x (e^(n ArcCoth[a x])))/(((c+d (x^2)))^(3/2)))dx  when  (a^2) c+d==0 ∧ n∉ℤ

Rule: If  (a^2) c+d==0 ∧ n∉ℤ, then

∫((x (e^(n ArcCoth[a x])))/(((c+d (x^2)))^(3/2)))dx  ⟶  -(((1-a n x) (e^(n ArcCoth[a x])))/((a^2) c ((n^2)-1) (Sqrt[c+d (x^2)])))

Program code:

Int[x_*E^(n_*ArcCoth[a_.*x_])/(c_+d_.*x_^2)^(3/2),x_Symbol] :=
  -(1-a*n*x)*E^(n*ArcCoth[a*x])/(a^2*c*(n^2-1)*Sqrt[c+d*x^2]) /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[n]]

2:  ∫x(((c+d (x^2)))^p)(e^(n ArcCoth[a x]))dx  when  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ p≤-1 ∧ p≠-(3/2) ∧ (n^2)-4(((p+1))^2)≠0

Rule: If  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ p≤-1 ∧ p≠-(3/2) ∧ (n^2)-4(((p+1))^2)≠0 ∧ p∉ℤ, then

∫x(((c+d (x^2)))^p)(e^(n ArcCoth[a x]))dx  ⟶  (((2(p+1)+a n x)(((c+d (x^2)))^(p+1))(e^(n ArcCoth[a x])))/((a^2) c ((n^2)-4(((p+1))^2))))-((n(2p+3))/(a c ((n^2)-4(((p+1))^2))))∫(((c+d (x^2)))^(p+1))(e^(n ArcCoth[a x]))dx

Program code:

Int[x_*(c_+d_.*x_^2)^p_*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  (2*(p+1)+a*n*x)*(c+d*x^2)^(p+1)*E^(n*ArcCoth[a*x])/(a^2*c*(n^2-4*(p+1)^2)) - 
  n*(2*p+3)/(a*c*(n^2-4*(p+1)^2))*Int[(c+d*x^2)^(p+1)*E^(n*ArcCoth[a*x]),x] /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[n/2]] && LeQ[p,-1] && NeQ[p,-3/2] && NeQ[n^2-4*(p+1)^2,0] && (IntegerQ[p] || Not[IntegerQ[n]])

2.  ∫(x^2)(((c+d (x^2)))^p)(e^(n ArcCoth[a x]))dx  when  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ p≤-1

1:  ∫(x^2)(((c+d (x^2)))^p) (e^(n ArcCoth[a x]))dx  when  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ (n^2)+2(p+1)==0 ∧ (n^2)≠1

Rule: If  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ (n^2)+2(p+1)==0 ∧ (n^2)≠1, then

∫(x^2)(((c+d (x^2)))^p) (e^(n ArcCoth[a x]))dx  ⟶  -(((n+2(p+1) a x)(((c+d (x^2)))^(p+1))(e^(n ArcCoth[a x])))/((a^3)c (n^2)((n^2)-1)))

Program code:

Int[x_^2*(c_+d_.*x_^2)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -(n+2*(p+1)*a*x)*(c+d*x^2)^(p+1)*E^(n*ArcCoth[a*x])/(a^3*c*n^2*(n^2-1)) /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[n/2]] && EqQ[n^2+2*(p+1),0] && NeQ[n^2,1]

2:  ∫(x^2)(((c+d (x^2)))^p)(e^(n ArcCoth[a x]))dx  when  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ p≤-1 ∧ (n^2)+2(p+1)≠0 ∧ (n^2)-4(((p+1))^2)≠0

Rule: If  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ p≤-1 ∧ (n^2)+2(p+1)≠0 ∧ (n^2)-4(((p+1))^2)≠0, then

∫(x^2)(((c+d (x^2)))^p)(e^(n ArcCoth[a x]))dx  ⟶  (((n+2(p+1) a x)(((c+d (x^2)))^(p+1))(e^(n ArcCoth[a x])))/((a^3)c((n^2)-4(((p+1))^2))))-(((n^2)+2(p+1))/((a^2) c((n^2)-4(((p+1))^2))))∫(((c+d (x^2)))^(p+1))(e^(n ArcCoth[a x]))dx

Program code:

Int[x_^2*(c_+d_.*x_^2)^p_*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  (n+2*(p+1)*a*x)*(c+d*x^2)^(p+1)*E^(n*ArcCoth[a*x])/(a^3*c*(n^2-4*(p+1)^2)) - 
  (n^2+2*(p+1))/(a^2*c*(n^2-4*(p+1)^2))*Int[(c+d*x^2)^(p+1)*E^(n*ArcCoth[a*x]),x] /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[n/2]] && LeQ[p,-1] && NeQ[n^2+2*(p+1),0] && NeQ[n^2-4*(p+1)^2,0] && 
  (IntegerQ[p] || Not[IntegerQ[n]])

3:  ∫(x^m)(((c+d (x^2)))^p)(e^(n ArcCoth[a x]))dx  when  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ m∈ℤ ∧ 3≤m≤-2(p+1) ∧ p∈ℤ

Derivation: Integration by substitution

Basis: If  (a^2) c+d==0 ∧ m∈ℤ ∧ p∈ℤ, then (x^m)(((c+d (x^2)))^p)(e^(n ArcCoth[a x]))==-((((-c))^p)/(a^(m+1)))(((e^(n ArcCoth[a x])) ((Coth[ArcCoth[a x]])^(m+2 (p+1))))/((Cosh[ArcCoth[a x]])^(2 (p+1))))(∂_x)ArcCoth[a x]

Rule: If  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ m∈ℤ ∧ 3≤m≤-2(p+1) ∧ p∈ℤ, then

∫(x^m)(((c+d (x^2)))^p)(e^(n ArcCoth[a x]))dx  ⟶  -((((-c))^p)/(a^(m+1))) Subst[∫(((e^(n x)) ((Coth[x])^(m+2 (p+1))))/((Cosh[x])^(2 (p+1))))dx,x,ArcCoth[a x]]

Program code:

Int[x_^m_.*(c_+d_.*x_^2)^p_*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -(-c)^p/a^(m+1)*Subst[Int[E^(n*x)*Coth[x]^(m+2*(p+1))/Cosh[x]^(2*(p+1)),x],x,ArcCoth[a*x]] /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[n/2]] && IntegerQ[m] && LeQ[3,m,-2(p+1)] && IntegerQ[p]

3.  ∫u(((c+d (x^2)))^p)(e^(n ArcCoth[a x]))dx  when  (a^2) c+d==0 ∧ (n/2)∉ℤ

1:  ∫u(((c+d (x^2)))^p) (e^(n ArcCoth[a x]))dx  when  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  (a^2) c+d==0 ∧ p∈ℤ, then (((c+d (x^2)))^p)==(d^p)(x^(2 p))(((1-(1/((a^2)(x^2)))))^p)

Rule: If  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ p∈ℤ, then

∫u(((c+d (x^2)))^p) (e^(n ArcCoth[a x]))dx  ⟶  (d^p)∫u (x^(2 p))(((1-(1/((a^2)(x^2)))))^p) (e^(n ArcCoth[a x]))dx

Program code:

Int[u_.*(c_+d_.*x_^2)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  d^p*Int[u*x^(2*p)*(1-1/(a^2*x^2))^p*E^(n*ArcCoth[a*x]),x] /;
FreeQ[{a,c,d,n},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[n/2]] && IntegerQ[p]

2:  ∫u(((c+d (x^2)))^p) (e^(n ArcCoth[a x]))dx  when  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (a^2) c+d==0, then (∂_x)((((c+d (x^2)))^p)/((x^(2p))(((1-(1/((a^2)(x^2)))))^p)))==0

Rule: If  (a^2) c+d==0 ∧ (n/2)∉ℤ ∧ p∉ℤ, then

∫u(((c+d (x^2)))^p) (e^(n ArcCoth[a x]))dx  ⟶  ((((c+d (x^2)))^p)/((x^(2p))(((1-(1/((a^2)(x^2)))))^p)))∫u (x^(2 p))(((1-(1/((a^2)(x^2)))))^p) (e^(n ArcCoth[a x]))dx

Program code:

Int[u_.*(c_+d_.*x_^2)^p_*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  (c+d*x^2)^p/(x^(2*p)*(1-1/(a^2*x^2))^p)*Int[u*x^(2*p)*(1-1/(a^2*x^2))^p*E^(n*ArcCoth[a*x]),x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[a^2*c+d,0] && Not[IntegerQ[n/2]] && Not[IntegerQ[p]]

5.  ∫u(((c+(d/(x^2))))^p) (e^(n ArcCoth[a x]))dx  when  c+(a^2)d==0 ∧ (n/2)∉ℤ

1.  ∫u(((c+(d/(x^2))))^p) (e^(n ArcCoth[a x]))dx  when  c+(a^2)d==0 ∧ (n/2)∉ℤ ∧ (p∈ℤ ∨ c>0)

1:  ∫u(((c+(d/(x^2))))^p) (e^(n ArcCoth[a x]))dx  when  c+(a^2)d==0 ∧ (n/2)∉ℤ ∧ (p∈ℤ ∨ c>0) ∧ (2p|p+(n/2))∈ℤ

Derivation: Algebraic simplification

Basis: (e^(n ArcCoth[z]))==((((1+(1/z)))^(n/2))/(((1-(1/z)))^(n/2)))

Basis: (((1-(z^2)))^p)==(((1-z))^p)(((1+z))^p)

Basis: If  p+n∈ℤ, then (((1-(1/z)))^(p-n))(((1+(1/z)))^(p+n))==(((((-1+z))^(p-n)) (((1+z))^(p+n)))/(z^(2 p)))

Rule: If  c+(a^2)d==0 ∧ (n/2)∉ℤ ∧ (p∈ℤ ∨ c>0) ∧ (2p|p+(n/2))∈ℤ, then

∫u(((c+(d/(x^2))))^p) (e^(n ArcCoth[a x]))dx  ⟶  (c^p)∫u(((1-(1/((a^2)(x^2)))))^p)((((1+(1/(a x))))^(n/2))/(((1-(1/(a x))))^(n/2)))dx                                    
                                ⟶  (c^p)∫u(((1-(1/(a x))))^(p-(n/2)))(((1+(1/(a x))))^(p+(n/2)))dx
                                           ⟶  ((c^p)/(a^(2 p)))∫(u/(x^(2 p)))(((-1+a x))^(p-(n/2))) (((1+a x))^(p+(n/2)))dx

Program code:

Int[u_.*(c_+d_./x_^2)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  c^p/a^(2*p)*Int[u/x^(2*p)*(-1+a*x)^(p-n/2)*(1+a*x)^(p+n/2),x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[c+a^2*d,0] && Not[IntegerQ[n/2]] && (IntegerQ[p] || GtQ[c,0]) && IntegersQ[2*p,p+n/2]

2.  ∫(x^m)(((c+(d/(x^2))))^p) (e^(n ArcCoth[a x]))dx  when  c+(a^2)d==0 ∧ (n/2)∉ℤ ∧ (p∈ℤ ∨ c>0) ∧ ¬(2p|p+(n/2))∈ℤ

1:  ∫(x^m)(((c+(d/(x^2))))^p)(e^(n ArcCoth[a x]))dx  when  c+(a^2)d==0 ∧ (n/2)∉ℤ ∧ (p∈ℤ ∨ c>0) ∧ ¬(2p|p+(n/2))∈ℤ ∧ m∈ℤ

Derivation: Algebraic simplification and integration by substitution

Basis: (e^(n ArcCoth[z]))==((((1+(1/z)))^(n/2))/(((1-(1/z)))^(n/2)))

Basis: (((1-(z^2)))^p)==(((1-z))^p)(((1+z))^p)

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If  c+(a^2)d==0 ∧ (n/2)∉ℤ ∧ (p∈ℤ ∨ c>0) ∧ ¬(2p|p+(n/2))∈ℤ, then

∫(x^m)(((c+(d/(x^2))))^p)(e^(n ArcCoth[a x]))dx  ⟶  (c^p)∫(x^m)(((1-(1/((a^2)(x^2)))))^p)((((1+(1/(a x))))^(n/2))/(((1-(1/(a x))))^(n/2)))dx                                
                                               ⟶  (c^p)∫(1/((((1/x)))^m))(((1-(1/(a x))))^(p-(n/2)))(((1+(1/(a x))))^(p+(n/2)))dx
                                                              ⟶  -(c^p)Subst[∫(((((1-(x/a)))^(p-(n/2))) (((1+(x/a)))^(p+(n/2))))/(x^(m+2)))dx,x,(1/x)]

Program code:

Int[(c_+d_./x_^2)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -c^p*Subst[Int[(1-x/a)^(p-n/2)*(1+x/a)^(p+n/2)/x^2,x],x,1/x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[c+a^2*d,0] && Not[IntegerQ[n/2]] && (IntegerQ[p] || GtQ[c,0]) && Not[IntegersQ[2*p,p+n/2]]

Int[x_^m_.*(c_+d_./x_^2)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -c^p*Subst[Int[(1-x/a)^(p-n/2)*(1+x/a)^(p+n/2)/x^(m+2),x],x,1/x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[c+a^2*d,0] && Not[IntegerQ[n/2]] && (IntegerQ[p] || GtQ[c,0]) && Not[IntegersQ[2*p,p+n/2]] && IntegerQ[m]

2:  ∫(x^m)(((c+(d/(x^2))))^p)(e^(n ArcCoth[a x]))dx  when  c+(a^2)d==0 ∧ (n/2)∉ℤ ∧ (p∈ℤ ∨ c>0) ∧ ¬(2p|p+(n/2))∈ℤ ∧ m∉ℤ

Derivation: Algebraic simplification, piecewise constant extraction and integration by substitution

Basis: (e^(n ArcCoth[z]))==((((1+(1/z)))^(n/2))/(((1-(1/z)))^(n/2)))

Basis: (((1-(z^2)))^p)==(((1-z))^p)(((1+z))^p)

Basis: (∂_x)((x^m) ((((1/x)))^m))==0

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If  c+(a^2)d==0 ∧ (n/2)∉ℤ ∧ (p∈ℤ ∨ c>0) ∧ ¬(2p|p+(n/2))∈ℤ, then

∫(x^m)(((c+(d/(x^2))))^p)(e^(n ArcCoth[a x]))dx  ⟶  (c^p)∫(x^m)(((1-(1/((a^2)(x^2)))))^p)((((1+(1/(a x))))^(n/2))/(((1-(1/(a x))))^(n/2)))dx                                         
                                                           ⟶  (c^p)(x^m)((((1/x)))^m)∫(1/((((1/x)))^m))(((1-(1/(a x))))^(p-(n/2)))(((1+(1/(a x))))^(p+(n/2)))dx
                                                                          ⟶  -(c^p)(x^m)((((1/x)))^m)Subst[∫(((((1-(x/a)))^(p-(n/2))) (((1+(x/a)))^(p+(n/2))))/(x^(m+2)))dx,x,(1/x)]

Program code:

Int[x_^m_*(c_+d_./x_^2)^p_.*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  -c^p*x^m*(1/x)^m*Subst[Int[(1-x/a)^(p-n/2)*(1+x/a)^(p+n/2)/x^(m+2),x],x,1/x] /;
FreeQ[{a,c,d,m,n,p},x] && EqQ[c+a^2*d,0] && Not[IntegerQ[n/2]] && (IntegerQ[p] || GtQ[c,0]) && Not[IntegersQ[2*p,p+n/2]] && Not[IntegerQ[m]]

2:  ∫u(((c+(d/(x^2))))^p)(e^(n ArcCoth[a x]))dx  when  c+(a^2)d==0 ∧ (n/2)∉ℤ ∧ ¬(p∈ℤ ∨ c>0)

Derivation: Piecewise constant extraction

Basis: If  c+(a^2)d==0, then (∂_x)((((c+(d/(x^2))))^p)/(((1-(1/((a^2)(x^2)))))^p))==0

Rule: If  c+(a^2)d==0 ∧ (n/2)∉ℤ ∧ ¬(p∈ℤ ∨ c>0), then

∫u(((c+(d/(x^2))))^p) (e^(n ArcCoth[a x]))dx  ⟶  (((c^(IntPart[p]))(((c+(d/(x^2))))^(FracPart[p])))/(((1-(1/((a^2)(x^2)))))^(FracPart[p])))∫u(((1-(1/((a^2)(x^2)))))^p) (e^(n ArcCoth[a x]))dx

Program code:

Int[u_.*(c_+d_./x_^2)^p_*E^(n_.*ArcCoth[a_.*x_]),x_Symbol] :=
  c^IntPart[p]*(c+d/x^2)^FracPart[p]/(1-1/(a^2*x^2))^FracPart[p]*Int[u*(1-1/(a^2*x^2))^p*E^(n*ArcCoth[a*x]),x] /;
FreeQ[{a,c,d,n,p},x] && EqQ[c+a^2*d,0] && Not[IntegerQ[n/2]] && Not[IntegerQ[p] || GtQ[c,0]]

2.  ∫u (e^(n ArcCoth[a+b x]))dx

1:  ∫u (e^(n ArcCoth[a+b x]))dx  when  (n/2)∈ℤ

Derivation: Algebraic simplification

Basis: If (n/2)∈ℤ, then (e^(n ArcCoth[z]))==(((-1))^(n/2))(e^(n ArcTanh[z]))

Rule: If  (n/2)∈ℤ, then

∫u (e^(n ArcCoth[c (a+b x)]))dx  ⟶  (((-1))^(n/2))∫u (e^(n ArcTanh[c (a+b x)]))dx

Program code:

Int[u_.*E^(n_*ArcCoth[c_.*(a_+b_.*x_)]),x_Symbol] :=
  (-1)^(n/2)*Int[u*E^(n*ArcTanh[c*(a+b*x)]),x] /;
FreeQ[{a,b,c},x] && IntegerQ[n/2]

2.  ∫u (e^(n ArcCoth[a+b x]))dx  when  (n/2)∉ℤ

1:  ∫(e^(n ArcCoth[c (a+b x)]))dx  when  (n/2)∉ℤ

Derivation: Algebraic simplification and piecewise constant extraction

Basis: (e^(n ArcCoth[z]))==((((1+(1/z)))^(n/2))/(((1-(1/z)))^(n/2)))==(((z^(n/2))(((1+(1/z)))^(n/2)))/(((-1+z))^(n/2)))

Basis: (∂_x)((((f[x])^n) (((1+(1/(f[x]))))^n))/(((1+f[x]))^n))==0

Rule: If  (n/2)∉ℤ, then

∫(e^(n ArcCoth[c (a+b x)]))dx  ⟶  ∫(((((c (a+b x)))^(n/2))(((1+(1/(c (a+b x)))))^(n/2)))/(((-1+c (a+b x)))^(n/2)))dx  ⟶  (((((c (a+b x)))^(n/2)) (((1+(1/(c (a+b x)))))^(n/2)))/(((1+a c+b c x))^(n/2)))∫((((1+a c+b c x))^(n/2))/(((-1+a c+b c x))^(n/2)))dx

Program code:

Int[E^(n_.*ArcCoth[c_.*(a_+b_.*x_)]),x_Symbol] :=
  (c*(a+b*x))^(n/2)*(1+1/(c*(a+b*x)))^(n/2)/(1+a*c+b*c*x)^(n/2)*Int[(1+a*c+b*c*x)^(n/2)/(-1+a*c+b*c*x)^(n/2),x] /;
FreeQ[{a,b,c,n},x] && Not[IntegerQ[n/2]]

2.  ∫(((d+e x))^m) (e^(n ArcCoth[c (a+b x)]))dx  when  (n/2)∉ℤ

1:  ∫(x^m) (e^(n ArcCoth[c (a+b x)]))dx  when  m∈(SuperMinus[ℤ])∧ -1<n<1

Derivation: Algebraic simplification and integration by substitution

Basis: (e^(n ArcCoth[z]))==((((1+(1/z)))^(n/2))/(((1-(1/z)))^(n/2)))

Basis: If  m∈ℤ ∧ -1<n<1 , then (x^m)((((1+(1/(c (a+b x)))))^(n/2))/(((1-(1/(c (a+b x)))))^(n/2)))==-(4/(n (b^(m+1))(c^(m+1))))Subst[(((x^(2/n)) (((1+a c+(1-a c) (x^(2/n))))^m))/(((-1+(x^(2/n))))^(m+2))),x,((((1+(1/(c (a+b x)))))^(n/2))/(((1-(1/(c (a+b x)))))^(n/2)))](∂_x)((((1+(1/(c (a+b x)))))^(n/2))/(((1-(1/(c (a+b x)))))^(n/2)))

Note: There should be an algebraic substitution rule that makes this rule redundant.

Rule: If  m∈(SuperMinus[ℤ])∧ -1<n<1 , then

∫(x^m) (e^(n ArcCoth[c (a+b x)]))dx  ⟶  ∫(x^m)((((1+(1/(c (a+b x)))))^(n/2))/(((1-(1/(c (a+b x)))))^(n/2)))dx                                                                                                
                                                                             ⟶  -(4/(n (b^(m+1))(c^(m+1))))Subst[∫(((x^(2/n)) (((1+a c+(1-a c) (x^(2/n))))^m))/(((-1+(x^(2/n))))^(m+2)))dx,x,((((1+(1/(c (a+b x)))))^(n/2))/(((1-(1/(c (a+b x)))))^(n/2)))]

Program code:

Int[x_^m_*E^(n_*ArcCoth[c_.*(a_+b_.*x_)]),x_Symbol] :=
  -4/(n*b^(m+1)*c^(m+1))*
    Subst[Int[x^(2/n)*(1+a*c+(1-a*c)*x^(2/n))^m/(-1+x^(2/n))^(m+2),x],x,(1+1/(c*(a+b*x)))^(n/2)/(1-1/(c*(a+b*x)))^(n/2)] /;
FreeQ[{a,b,c},x] && ILtQ[m,0] && LtQ[-1,n,1]

2:  ∫(((d+e x))^m) (e^(n ArcCoth[c (a+b x)]))dx  when  (n/2)∉ℤ

Derivation: Algebraic simplification and piecewise constant extraction

Basis: (e^(n ArcCoth[z]))==((((1+(1/z)))^(n/2))/(((1-(1/z)))^(n/2)))==(((z^(n/2))(((1+(1/z)))^(n/2)))/(((-1+z))^(n/2)))

Basis: (∂_x)((((f[x])^n) (((1+(1/(f[x]))))^n))/(((1+f[x]))^n))==0

Rule: If  (n/2)∉ℤ, then

∫(((d+e x))^m) (e^(n ArcCoth[c (a+b x)]))dx  ⟶  ∫(((d+e x))^m)(((((c (a+b x)))^(n/2))(((1+(1/(c (a+b x)))))^(n/2)))/(((-1+c (a+b x)))^(n/2)))dx
  ⟶  (((((c (a+b x)))^(n/2)) (((1+(1/(c (a+b x)))))^(n/2)))/(((1+a c+b c x))^(n/2)))∫(((d+e x))^m)((((1+a c+b c x))^(n/2))/(((-1+a c+b c x))^(n/2)))dx

Program code:

Int[(d_.+e_.*x_)^m_.*E^(n_.*ArcCoth[c_.*(a_+b_.*x_)]),x_Symbol] :=
  (c*(a+b*x))^(n/2)*(1+1/(c*(a+b*x)))^(n/2)/(1+a*c+b*c*x)^(n/2)*Int[(d+e*x)^m*(1+a*c+b*c*x)^(n/2)/(-1+a*c+b*c*x)^(n/2),x] /;
FreeQ[{a,b,c,d,e,m,n},x] && Not[IntegerQ[n/2]]

3.  ∫u(((c+d x+e (x^2)))^p)(e^(n ArcCoth[a+b x]))dx  when  (n/2)∉ℤ ∧ b d==2 a e ∧ (b^2) c+e(1-(a^2))==0

1:  ∫u(((c+d x+e (x^2)))^p) (e^(n ArcCoth[a+b x]))dx  when  (n/2)∉ℤ ∧ b d==2 a e ∧ (b^2) c+e(1-(a^2))==0 ∧ (p∈ℤ ∨ (c/(1-(a^2)))>0)

Derivation: Algebraic simplification and piecewise constant extraction

Basis: If  b d==2 a e ∧ (b^2) c+e(1-(a^2))==0, then c+d x+e (x^2)==(c/(1-(a^2)))(1-(((a+b x))^2))

Basis: (e^(n ArcCoth[z]))==((((1+(1/z)))^(n/2))/(((1-(1/z)))^(n/2)))==(((z^(n/2))(((1+(1/z)))^(n/2)))/(((-1+z))^(n/2)))

Basis: (∂_x)(((((a+b x))^n)(((1+(1/(a+b x))))^n))/(((1+a+b x))^n))==0

Basis: (∂_x)((((1-a-b x))^n)/(((-1+a+b x))^n))==0

Basis: (((1-(z^2)))^p)==(((1-z))^p)(((1+z))^p)

Basis: (((z^n)(((1+(1/z)))^n))/(((1+z))^n))==((((z/(1+z))))^n) (((((1+z)/z)))^n)

Rule: If  (n/2)∉ℤ ∧ b d==2 a e ∧ (b^2) c+e(1-(a^2))==0 ∧ (p∈ℤ ∨ (c/(1-(a^2)))>0), then

∫u(((c+d x+e (x^2)))^p) (e^(n ArcCoth[a+b x]))dx  ⟶  ((((c/(1-(a^2)))))^p)∫u(((1-(((a+b x))^2)))^p) (((((a+b x))^(n/2))(((1+(1/(a+b x))))^(n/2)))/(((-1+a+b x))^(n/2)))dx                                                                          
                                                                                 ⟶  ((((c/(1-(a^2)))))^p)(((((a+b x))^(n/2))(((1+(1/(a+b x))))^(n/2)))/(((1+a+b x))^(n/2)))((((1-a-b x))^(n/2))/(((-1+a+b x))^(n/2)))∫u(((1-(((a+b x))^2)))^p) ((((1+a+b x))^(n/2))/(((1-a-b x))^(n/2)))dx  
                                                                                            ⟶  ((((c/(1-(a^2)))))^p)(((((a+b x)/(1+a+b x))))^(n/2)) (((((1+a+b x)/(a+b x))))^(n/2))((((1-a-b x))^(n/2))/(((-1+a+b x))^(n/2)))∫u(((1-a-b x))^(p-n/2))(((1+a+b x))^(p+n/2))dx

Program code:

Int[u_.*(c_+d_.*x_+e_.*x_^2)^p_.*E^(n_.*ArcCoth[a_+b_.*x_]),x_Symbol] :=
  (c/(1-a^2))^p*((a+b*x)/(1+a+b*x))^(n/2)*((1+a+b*x)/(a+b*x))^(n/2)*((1-a-b*x)^(n/2)/(-1+a+b*x)^(n/2))*
    Int[u*(1-a-b*x)^(p-n/2)*(1+a+b*x)^(p+n/2),x] /;
FreeQ[{a,b,c,d,e,n,p},x] && Not[IntegerQ[n/2]] && EqQ[b*d-2*a*e,0] && EqQ[b^2*c+e(1-a^2),0] && (IntegerQ[p] || GtQ[c/(1-a^2),0])

2:  ∫u(((c+d x+e (x^2)))^p) (e^(n ArcCoth[a+b x]))dx  when  (n/2)∉ℤ ∧ b d==2 a e ∧ (b^2) c+e(1-(a^2))==0 ∧ ¬(p∈ℤ ∨ (c/(1-(a^2)))>0)

Derivation: Piecewise constant extraction

Basis: If  b d==2 a e ∧ (b^2) c+e(1-(a^2))==0, then (∂_x)((((c+d x+e (x^2)))^p)/(((1-(a^2)-2 a b x-(b^2) (x^2)))^p))==0

Rule: If  b d==2 a e ∧ (b^2) c+e(1-(a^2))==0 ∧ ¬(p∈ℤ ∨ (c/(1-(a^2)))>0), then

∫u(((c+d x+e (x^2)))^p) (e^(n ArcCoth[a+b x]))dx  ⟶  ((((c+d x+e (x^2)))^p)/(((1-(a^2)-2 a b x-(b^2) (x^2)))^p))∫u(((1-(a^2)-2 a b x-(b^2) (x^2)))^p) (e^(n ArcCoth[a+b x]))dx

Program code:

Int[u_.*(c_+d_.*x_+e_.*x_^2)^p_.*E^(n_.*ArcCoth[a_+b_.*x_]),x_Symbol] :=
  (c+d*x+e*x^2)^p/(1-a^2-2*a*b*x-b^2*x^2)^p*Int[u*(1-a^2-2*a*b*x-b^2*x^2)^p*E^(n*ArcCoth[a*x]),x] /;
FreeQ[{a,b,c,d,e,n,p},x] && Not[IntegerQ[n/2]] && EqQ[b*d-2*a*e,0] && EqQ[b^2*c+e(1-a^2),0] && Not[IntegerQ[p] || GtQ[c/(1-a^2),0]]

3:  ∫u (e^(n ArcCoth[(c/(a+b x))]))dx

Derivation: Algebraic simplification

Basis: ArcCoth[z]==ArcTanh[(1/z)]

Rule:

∫u (e^(n ArcCoth[(c/(a+b x))]))dx  ⟶  ∫u (e^(n ArcTanh[(a/c)+((b x)/c)]))dx

Program code:

Int[u_.*E^(n_.*ArcCoth[c_./(a_.+b_.*x_)]),x_Symbol] :=
  Int[u*E^(n*ArcTanh[a/c+b*x/c]),x] /;
FreeQ[{a,b,c,n},x]